cppcodec/repos/extra-any/PKGBUILD

   1 # Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
   2
   3 pkgname=cppcodec
   4 pkgver=0.2
   5 pkgrel=3
   6 pkgdesc='Header-only C++11 library to encode/decode base64, base64url, base32, base32hex and hex'
   7 url='https://github.com/tplgy/cppcodec'
   8 arch=('any')
   9 license=('MIT')
  10 makedepends=('cmake' 'catch2')
  11 source=(${url}/archive/v${pkgver}/${pkgname}-${pkgver}.tar.gz)
  12 sha512sums=('50c9c81cdb12560c87e513e1fd22c1ad24ea37b7d20a0e3044d43fb887f4c6494c69468e4d0811cd2fc1ae8fdb01b01cfb9f3cfdd8611d4bb0221cbd38cbead3')
  13 b2sums=('248487326d3fafb104d469d16cddab86fe63dec6eecb74af6211c262a42ff8806ee97619459f9dca648107748e30268206e84d64efba47a9ea1c398eb4c06919')
  14
  15 build() {
  16   cd ${pkgname}-${pkgver}
  17   cmake \
  18     -DCMAKE_BUILD_TYPE=None \
  19     -DCMAKE_INSTALL_PREFIX=/usr \
  20     -Wno-dev \
  21     -B build
  22   make -C build
  23 }
  24
  25 check() {
  26   cd ${pkgname}-${pkgver}
  27   make -C build test
  28 }
  29
  30 package() {
  31   cd ${pkgname}-${pkgver}
  32   make -C build DESTDIR="${pkgdir}" install
  33   install -Dm 644 LICENSE -t "${pkgdir}/usr/share/licenses/${pkgname}"
  34   install -Dm 644 README.md -t "${pkgdir}/usr/share/doc/${pkgname}"
  35   install -Dm 644 example/* -t "${pkgdir}/usr/share/doc/${pkgname}/example"
  36 }
  37
  38 # vim: ts=2 sw=2 et: