dav1d/trunk/PKGBUILD

   1 # Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
   2
   3 pkgbase=dav1d
   4 pkgname=(dav1d dav1d-doc)
   5 pkgver=1.2.0
   6 pkgrel=1
   7 pkgdesc='AV1 cross-platform decoder focused on speed and correctness'
   8 url='https://code.videolan.org/videolan/dav1d/'
   9 arch=('x86_64')
  10 license=('BSD')
  11 makedepends=('meson' 'ninja' 'nasm' 'doxygen' 'graphviz' 'xxhash')
  12 source=(https://downloads.videolan.org/pub/videolan/${pkgname}/${pkgver}/${pkgname}-${pkgver}.tar.xz{,.asc}
  13         https://code.videolan.org/videolan/dav1d-test-data/-/archive/${pkgver}/dav1d-test-data-${pkgver}.tar.gz)
  14 sha512sums=('1f1775bdcdbc38a0bb12d7f14f01ee321cc03f15d8b7c6fabe2ada3a3c46885b0eff5851ea912079a1519ef01278c3a192e3b0347b0ab9b25cafab4124f1ae6a'
  15             'SKIP'
  16             'f91d724989b2671911dae8f46a39c2b25b89356923b255bbd249f9a4529daaadc176098928d91e930989d647515f4f403dfe23bbfcd5adc1fa86b32d195bc0fa')
  17 b2sums=('f9c9ca8c48ba2cae8e2137bb46e9db9a2070b3fba35ca142fde836f20be8a0db11b3b0dc3f78d06780d5cf6d014b0a6b545368371f421864d3f30a35ca6fe5ef'
  18         'SKIP'
  19         '89ba3eb72b566ee12cff65db12f76d8cd23debb883a3f25d054799c18752a9b679656818fcb7ab3b5405259afaec28d0b49b42ec732004e85d42cabaa07bd103')
  20 validpgpkeys=('65F7C6B4206BD057A7EB73787180713BE58D1ADC') # VideoLAN Release Signing Key
  21
  22 prepare() {
  23   cd ${pkgbase}-${pkgver}
  24   ln -s "${srcdir}/dav1d-test-data-${pkgver}" tests/dav1d-test-data
  25 }
  26
  27 build() {
  28   cd ${pkgbase}-${pkgver}
  29   arch-meson \
  30     -Dtestdata_tests=true \
  31     -Denable_docs=true \
  32     build
  33   ninja -C build all doc/html
  34 }
  35
  36 check() {
  37   cd ${pkgbase}-${pkgver}/build
  38   meson test
  39 }
  40
  41 package_dav1d() {
  42   depends=('glibc')
  43   provides=('libdav1d.so')
  44   optdepends=('dav1d-doc: HTML documentation')
  45
  46   cd ${pkgbase}-${pkgver}
  47   DESTDIR="${pkgdir}" ninja -C build install
  48   install -Dm 644 README.md CONTRIBUTING.md NEWS -t "${pkgdir}/usr/share/doc/${pkgname}"
  49   install -Dm 644 COPYING -t "${pkgdir}/usr/share/licenses/${pkgname}"
  50 }
  51
  52 package_dav1d-doc() {
  53   pkgdesc+=" (documentation)"
  54
  55   cd ${pkgbase}-${pkgver}
  56   install -d "${pkgdir}/usr/share/doc/${pkgbase}"
  57   cp -r build/doc/html -t "${pkgdir}/usr/share/doc/${pkgbase}"
  58   install -Dm 644 COPYING -t "${pkgdir}/usr/share/licenses/${pkgname}"
  59 }
  60
  61 # vim: ts=2 sw=2 et: