devhelp/repos/extra-x86_64/PKGBUILD

   1 # Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
   2 # Contributor: Jan de Groot <jgc@archlinux.org>
   3 # Contributor: Link Dupont <link@subpop.net>
   4
   5 pkgbase=devhelp
   6 pkgname=(devhelp devhelp-docs)
   7 pkgver=43.0
   8 pkgrel=1
   9 pkgdesc="API documentation browser for GNOME"
  10 url="https://wiki.gnome.org/Apps/Devhelp"
  11 arch=(x86_64)
  12 license=(GPL)
  13 depends=(webkit2gtk-4.1)
  14 makedepends=(git appstream-glib gobject-introspection meson yelp-tools
  15              gi-docgen)
  16 options=(debug)
  17 _commit=f4e68f3f0134becbdd737eaac85caaa0a8e43a66  # tags/43.0^0
  18 source=("git+https://gitlab.gnome.org/GNOME/devhelp.git#commit=$_commit")
  19 sha256sums=('SKIP')
  20
  21 pkgver() {
  22   cd devhelp
  23   git describe --tags | sed 's/\.alpha/alpha/;s/[^-]*-g/r&/;s/-/+/g'
  24 }
  25
  26 prepare() {
  27   cd devhelp
  28 }
  29
  30 build() {
  31   local meson_options=(
  32     -D gtk_doc=true
  33     -D plugin_emacs=true
  34     -D plugin_gedit=true
  35     -D plugin_vim=true
  36   )
  37
  38   arch-meson devhelp build "${meson_options[@]}"
  39   meson compile -C build
  40 }
  41
  42 check() {
  43   meson test -C build --print-errorlogs
  44 }
  45
  46 package_devhelp() {
  47   groups=(gnome-extra)
  48
  49   meson install -C build --destdir "$pkgdir"
  50
  51   # Split -docs
  52   mkdir -p docs/usr/share
  53   mv -t docs/usr/share "$pkgdir"/usr/share/doc
  54 }
  55
  56 package_devhelp-docs() {
  57   pkgdesc+=" (documentation)"
  58   depends=()
  59
  60   mv -t "$pkgdir" docs/*
  61 }
  62
  63 # vim:set sw=2 sts=-1 et: