docbook-dsssl/repos/extra-any/PKGBUILD

   1 # Maintainer: Andreas Radke <andyrtr@archlinux.org>
   2
   3 # Contributor: Chris Severance aur.severach aATt spamgourmet dott com
   4 # Contributor: Andreas B. Wagner <AndreasBWagner@pointfree.net>
   5 # Contributor: Suat SARIALP <muhendis.suat@gmail.com>
   6
   7 pkgname='docbook-dsssl'
   8 pkgver=1.79
   9 pkgrel=9
  10 pkgdesc="DSSSL Stylesheets for DocBook"
  11 arch=('any')
  12 url="http://docbook.sourceforge.net/"
  13 license=('custom')
  14 depends=('sgml-common' 'perl')
  15 install=${pkgname}.install
  16 source=(https://sourceforge.net/projects/docbook/files/${pkgname}/${pkgver}/${pkgname}-${pkgver}.tar.bz2
  17         docbook-style-dsssl.Makefile)
  18 sha1sums=('0ee935247c9f850e930f3b5c162dbc03915469cd'
  19           '104a665b2c3e1520337533862cbd1c1c55d6e01c')
  20 sha256sums=('2f329e120bee9ef42fbdd74ddd60e05e49786c5a7953a0ff4c680ae6bdf0e2bc'
  21             '563662f6a3a0777f1ac037a0aebcfcdf7e9c8a8d3e042e69a33edffc0bcae1f1')
  22
  23 prepare() {
  24   cd "${pkgname}-${pkgver}"
  25   cp "${srcdir}"/docbook-style-dsssl.Makefile Makefile
  26 }
  27
  28 package(){
  29   cd "${pkgname}-${pkgver}"
  30   # FS#67286 parallel installation might fail
  31   make -j1 install \
  32      BINDIR="${pkgdir}/usr/bin" \
  33      DESTDIR="${pkgdir}/usr/share/sgml/docbook/dsssl-stylesheets-${pkgver}" \
  34      MANDIR="${pkgdir}/usr/share/man"
  35
  36   ln -s dsssl-stylesheets-${pkgver} ${pkgdir}/usr/share/sgml/docbook/dsssl-stylesheets
  37   # license
  38   install -Dm644 README "$pkgdir/usr/share/licenses/$pkgname/COPYING"
  39 }