efitools/trunk/PKGBUILD

   1 # Maintainer: David Runge <dvzrv@archlinux.org>
   2 # Contributor: Tobias Powalowski <tpowa@archlinux.org>
   3 # Contributor: Mirco Tischler <mt-ml at gmx dot de>
   4 # Contributor: Keshav Amburay <(the ddoott ridikulus ddoott rat) (aatt) (gemmaeiil) (ddoott) (ccoomm)>
   5
   6 pkgname=efitools
   7 pkgver=1.9.2
   8 pkgrel=5
   9 pkgdesc="Tools for manipulating UEFI secure boot platforms"
  10 url="https://git.kernel.org/pub/scm/linux/kernel/git/jejb/efitools.git/about/"
  11 arch=(x86_64)
  12 license=(GPL2 LGPL2.1)
  13 makedepends=(git gnu-efi-libs help2man perl-file-slurp sbsigntools)
  14 depends=(glibc openssl)
  15 source=("git+https://git.kernel.org/pub/scm/linux/kernel/git/jejb/$pkgname.git#tag=v${pkgver}?signed"
  16         "${pkgname}-1.9.2-console_warning_typo.patch")
  17 sha512sums=('SKIP'
  18             '9e609eb4fb2a7116166626d15470d66e2eb66a25867618d4065d48636304f88549a71c5e827ac92750183f0fabaa3b84beea3dffa905031a2867939bfae955e7')
  19 validpgpkeys=('D5606E73C8B46271BEAD9ADF814AE47C214854D6') # James Bottomley <jejb@kernel.org>
  20
  21 prepare() {
  22   cd "${pkgname}"
  23   patch -Np1 -i "../${pkgname}-1.9.2-console_warning_typo.patch"
  24 }
  25
  26 build() {
  27   # fix PreLoader.efi building on x86_64 #49314
  28   export ARCH="${CARCH}"
  29   # build with one job because the Makefile does not support parallel jobs ;_;
  30   # https://bugs.archlinux.org/task/73600
  31   make -j1 -C "${pkgname}"
  32 }
  33
  34 package() {
  35   make DESTDIR="${pkgdir}" install -C "${pkgname}"
  36   install -vDm 644 "${pkgname}/"README -t "${pkgdir}/usr/share/doc/${pkgname}"
  37 }