enchant/trunk/PKGBUILD

   1 # Maintainer: Felix Yan <felixonmars@gmail.com>
   2 # Contributor: Andrea Scarpino <andrea@archlinux.org>
   3 # Contributor: dorphell <dorphell@archlinux.org>
   4
   5 pkgname=enchant
   6 pkgver=2.3.4
   7 pkgrel=1
   8 pkgdesc="A wrapper library for generic spell checking"
   9 arch=('x86_64')
  10 url="https://abiword.github.io/enchant/"
  11 license=('LGPL')
  12 depends=('glib2')
  13 makedepends=('aspell' 'hunspell' 'hspell' 'nuspell' 'libvoikko')
  14 checkdepends=('unittestpp')
  15 optdepends=('aspell: for aspell based spell checking support'
  16             'hunspell: for hunspell based spell checking support'
  17             'libvoikko: for libvoikko based spell checking support'
  18             'hspell: for hspell based spell checking support'
  19             'nuspell: for nuspell based spell checking support')
  20 provides=('libenchant-2.so') # enchant_voikko.so enchant_nuspell.so enchant_hunspell.so enchant_hspell.so enchant_aspell.so)
  21 source=("https://github.com/AbiWord/enchant/releases/download/v$pkgver/enchant-$pkgver.tar.gz")
  22 sha512sums=('d109ab320ed84d6c9eec6c558c72a54d71ad30237c2bf11650b0e4030fbd9990a5ccf06a20851e46b6530279e1a9916b891cd394eefabc8812f7f92da62cbe1a')
  23
  24 prepare() {
  25   cd $pkgname-$pkgver
  26   autoreconf -vfi
  27 }
  28
  29 build() {
  30   cd $pkgname-$pkgver
  31   ./configure --prefix=/usr \
  32     --disable-static \
  33     --enable-relocatable
  34   sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
  35   make
  36 }
  37
  38 check() {
  39   cd $pkgname-$pkgver
  40   make check
  41 }
  42
  43 package() {
  44   cd $pkgname-$pkgver
  45   make DESTDIR="$pkgdir" install
  46 }