ffmpeg/trunk/PKGBUILD

   1 # Maintainer: Maxime Gauduin <alucryd@archlinux.org>
   2 # Contributor: Bartłomiej Piotrowski <bpiotrowski@archlinux.org>
   3 # Contributor: Ionut Biru <ibiru@archlinux.org>
   4 # Contributor: Tom Newsom <Jeepster@gmx.co.uk>
   5 # Contributor: Paul Mattal <paul@archlinux.org>
   6
   7 pkgname=ffmpeg
   8 pkgver=6.0
   9 pkgrel=6
  10 epoch=2
  11 pkgdesc='Complete solution to record, convert and stream audio and video'
  12 arch=(x86_64)
  13 url=https://ffmpeg.org/
  14 license=(GPL3)
  15 depends=(
  16   alsa-lib
  17   aom
  18   bzip2
  19   fontconfig
  20   fribidi
  21   gmp
  22   gnutls
  23   gsm
  24   jack
  25   lame
  26   libass.so
  27   libavc1394
  28   libbluray.so
  29   libbs2b.so
  30   libdav1d.so
  31   libdrm
  32   libfreetype.so
  33   libgl
  34   libiec61883
  35   libjxl.so
  36   libmfx
  37   libmodplug
  38   libopenmpt.so
  39   libpulse
  40   librav1e.so
  41   libraw1394
  42   librsvg-2.so
  43   libsoxr
  44   libssh
  45   libtheora
  46   libva.so
  47   libva-drm.so
  48   libva-x11.so
  49   libvdpau
  50   libvidstab.so
  51   libvorbisenc.so
  52   libvorbis.so
  53   libvpx.so
  54   libvulkan.so
  55   libwebp
  56   libx11
  57   libx264.so
  58   libx265.so
  59   libxcb
  60   libxext
  61   libxml2
  62   libxv
  63   libxvidcore.so
  64   libzimg.so
  65   ocl-icd
  66   opencore-amr
  67   openjpeg2
  68   opus
  69   sdl2
  70   speex
  71   srt
  72   svt-av1
  73   v4l-utils
  74   vmaf
  75   xz
  76   zlib
  77 )
  78 makedepends=(
  79   amf-headers
  80   avisynthplus
  81   clang
  82   ffnvcodec-headers
  83   git
  84   ladspa
  85   mesa
  86   nasm
  87   opencl-headers
  88   vulkan-headers
  89 )
  90 optdepends=(
  91   'avisynthplus: AviSynthPlus support'
  92   'intel-media-sdk: Intel QuickSync support'
  93   'ladspa: LADSPA filters'
  94   'nvidia-utils: Nvidia NVDEC/NVENC support'
  95 )
  96 provides=(
  97   libavcodec.so
  98   libavdevice.so
  99   libavfilter.so
 100   libavformat.so
 101   libavutil.so
 102   libpostproc.so
 103   libswresample.so
 104   libswscale.so
 105 )
 106 options=(
 107   debug
 108 )
 109 _tag=3949db4d261748a9f34358a388ee255ad1a7f0c0
 110 source=(
 111   git+https://git.ffmpeg.org/ffmpeg.git?signed#tag=${_tag}
 112   add-av_stream_get_first_dts-for-chromium.patch
 113 )
 114 b2sums=('SKIP'
 115         '555274228e09a233d92beb365d413ff5c718a782008075552cafb2130a3783cf976b51dfe4513c15777fb6e8397a34122d475080f2c4483e8feea5c0d878e6de')
 116 validpgpkeys=(DD1EC9E8DE085C629B3E1846B18E8928B3948D64) # Michael Niedermayer <michael@niedermayer.cc>
 117
 118 prepare() {
 119   cd ffmpeg
 120   patch -Np1 -i ../add-av_stream_get_first_dts-for-chromium.patch # https://crbug.com/1251779
 121 }
 122
 123 pkgver() {
 124   cd ffmpeg
 125   git describe --tags | sed 's/^n//'
 126 }
 127
 128 build() {
 129   cd ffmpeg
 130   ./configure \
 131     --prefix=/usr \
 132     --disable-debug \
 133     --disable-static \
 134     --disable-stripping \
 135     --enable-amf \
 136     --enable-avisynth \
 137     --enable-cuda-llvm \
 138     --enable-lto \
 139     --enable-fontconfig \
 140     --enable-gmp \
 141     --enable-gnutls \
 142     --enable-gpl \
 143     --enable-ladspa \
 144     --enable-libaom \
 145     --enable-libass \
 146     --enable-libbluray \
 147     --enable-libbs2b \
 148     --enable-libdav1d \
 149     --enable-libdrm \
 150     --enable-libfreetype \
 151     --enable-libfribidi \
 152     --enable-libgsm \
 153     --enable-libiec61883 \
 154     --enable-libjack \
 155     --enable-libjxl \
 156     --enable-libmfx \
 157     --enable-libmodplug \
 158     --enable-libmp3lame \
 159     --enable-libopencore_amrnb \
 160     --enable-libopencore_amrwb \
 161     --enable-libopenjpeg \
 162     --enable-libopenmpt \
 163     --enable-libopus \
 164     --enable-libpulse \
 165     --enable-librav1e \
 166     --enable-librsvg \
 167     --enable-libsoxr \
 168     --enable-libspeex \
 169     --enable-libsrt \
 170     --enable-libssh \
 171     --enable-libsvtav1 \
 172     --enable-libtheora \
 173     --enable-libv4l2 \
 174     --enable-libvidstab \
 175     --enable-libvmaf \
 176     --enable-libvorbis \
 177     --enable-libvpx \
 178     --enable-libwebp \
 179     --enable-libx264 \
 180     --enable-libx265 \
 181     --enable-libxcb \
 182     --enable-libxml2 \
 183     --enable-libxvid \
 184     --enable-libzimg \
 185     --enable-nvdec \
 186     --enable-nvenc \
 187     --enable-opencl \
 188     --enable-opengl \
 189     --enable-shared \
 190     --enable-version3 \
 191     --enable-vulkan
 192   make
 193   make tools/qt-faststart
 194   make doc/ff{mpeg,play}.1
 195 }
 196
 197 package() {
 198   make DESTDIR="${pkgdir}" -C ffmpeg install install-man
 199   install -Dm 755 ffmpeg/tools/qt-faststart "${pkgdir}"/usr/bin/
 200 }
 201
 202 # vim: ts=2 sw=2 et: