ffnvcodec-headers/trunk/PKGBUILD

   1 # Maintainer: Maxime Gauduin <alucryd@archlinux.org>
   2 # Contributor: Daniel Bermond <danielbermond@yahoo.com>
   3
   4 pkgname=ffnvcodec-headers
   5 pkgver=12.0.16.0
   6 pkgrel=1
   7 pkgdesc='FFmpeg version of headers required to interface with Nvidias codec APIs'
   8 arch=(any)
   9 url=https://git.videolan.org/?p=ffmpeg/nv-codec-headers.git
  10 license=(MIT)
  11 makedepends=(git)
  12 _tag=c5e4af74850a616c42d39ed45b9b8568b71bf8bf
  13 source=(git+https://git.videolan.org/git/ffmpeg/nv-codec-headers.git#tag=${_tag})
  14 sha256sums=(SKIP)
  15
  16 pkgver() {
  17   cd nv-codec-headers
  18
  19   git describe --tags | sed 's/^n//'
  20 }
  21
  22 build() {
  23   make PREFIX=/usr -C nv-codec-headers
  24   sed -n '4,25p' nv-codec-headers/include/ffnvcodec/nvEncodeAPI.h > LICENSE # Extract license
  25   sed -i '1,22s/^.\{,3\}//' LICENSE # Delete C comments
  26 }
  27
  28 package() {
  29   make PREFIX=/usr DESTDIR="${pkgdir}" -C nv-codec-headers install
  30   install -Dm 644 LICENSE -t "${pkgdir}"/usr/share/licenses/ffnvcodec-headers/
  31 }
  32
  33 # vim: ts=2 sw=2 et: