fluxbox/repos/extra-x86_64/PKGBUILD

   1 # Maintainer: Eric Bélanger <eric@archlinux.org>
   2
   3 pkgname=fluxbox
   4 _commit='9d8202f32338a3f08d3fa39057dc5eec5d97be4e'
   5 pkgver=1.3.7+211+g9d8202f3
   6 pkgrel=1
   7 pkgdesc='A lightweight and highly-configurable window manager'
   8 arch=('x86_64')
   9 url='http://www.fluxbox.org/'
  10 license=('MIT')
  11 depends=('fontconfig' 'libfontconfig.so' 'fribidi' 'libfribidi.so' 'imlib2'
  12          'libxft' 'libxinerama' 'libxpm' 'libxrandr')
  13 makedepends=('git')
  14 optdepends=('xorg-xmessage: for using the fbsetbg and fluxbox-generate_menu utilities')
  15 options=('!makeflags')
  16 source=("git+https://github.com/fluxbox/fluxbox.git#commit=${_commit}"
  17         'fluxbox.desktop')
  18 sha256sums=('SKIP'
  19             '2148a90aca653b596e9632264dbdbd8c7e673d732e4b04eee66a8ac1e68b3c5d')
  20
  21 pkgver() {
  22   cd "${pkgname}"
  23
  24   git describe --tags | sed 's/Release-//;s/_/./g;s/-/+/g'
  25 }
  26
  27 prepare() {
  28   cd "${pkgname}"
  29
  30   autoreconf -fi
  31 }
  32
  33 build() {
  34   cd "${pkgname}"
  35
  36   ./configure \
  37     --prefix=/usr \
  38     --enable-imlib2 \
  39     --enable-nls \
  40     --enable-xft \
  41     --enable-xinerama
  42   make
  43 }
  44
  45 package() {
  46   cd "${pkgname}"
  47
  48   make DESTDIR="${pkgdir}" install
  49
  50   install -D -m0644 "${srcdir}/fluxbox.desktop" "${pkgdir}/usr/share/xsessions/fluxbox.desktop"
  51   install -D -m0644 COPYING "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
  52 }