fmt/repos/extra-x86_64/PKGBUILD

   1 # Maintainer: Maxime Gauduin <alucryd@archlinux.org>
   2 # Contributor: Mihai Bişog <mihai.bisog@gmail.com>
   3
   4 pkgname=fmt
   5 pkgver=9.1.0
   6 pkgrel=4
   7 pkgdesc='Open-source formatting library for C++'
   8 arch=(x86_64)
   9 url=https://fmt.dev
  10 license=(MIT)
  11 depends=(gcc-libs)
  12 makedepends=(
  13   cmake
  14   doxygen
  15   git
  16   ninja
  17   npm
  18   python-breathe
  19   python-docutils
  20   python-jinja
  21   python-six
  22   python-sphinx
  23   python-wheel
  24 )
  25 provides=(libfmt.so)
  26 _tag=a33701196adfad74917046096bf5a2aa0ab0bb50
  27 source=(
  28   git+https://github.com/fmtlib/fmt.git#tag=${_tag}
  29   fmt-no-pip-no-virtualenv.patch
  30 )
  31 b2sums=('SKIP'
  32         '4e19e7b2cd8fd049b7c692c0efbc4b2f1dd6062f44a600f4f47be81ed0ed14defb4285eb09b8d8fb8bb55441689c3a659e157e91d2cdd94e4d7b00c28b6534f2')
  33
  34 prepare() {
  35   cd fmt
  36   patch -Np1 -i ../fmt-no-pip-no-virtualenv.patch
  37   git cherry-pick -n 0b0f7cfbfcebd021c910078003d413354bd843e2 # hip workaround
  38 }
  39
  40 pkgver() {
  41   cd fmt
  42   git describe --tags
  43 }
  44
  45 build() {
  46   cmake -S fmt -B build -G Ninja \
  47     -DCMAKE_BUILD_TYPE=None \
  48     -DCMAKE_INSTALL_PREFIX=/usr \
  49     -DCMAKE_INSTALL_LIBDIR=/usr/lib \
  50     -DBUILD_SHARED_LIBS=ON
  51   cmake --build build
  52   cmake --build build --target doc
  53 }
  54
  55 check() {
  56   cmake --build build --target test
  57 }
  58
  59 package() {
  60   DESTDIR="${pkgdir}" cmake --build build --target install
  61   install -Dm 644 fmt/LICENSE.rst -t "${pkgdir}"/usr/share/licenses/fmt/
  62 }
  63
  64 # vim: ts=2 sw=2 et: