ftgl/trunk/PKGBUILD

   1 # Maintainer: Jan Alexander Steffens (heftig) <jan.steffens@gmail.com>
   2 # Contributor: Alexander Baldeck <alexander@archlinux.org>
   3 # Contributor: tobias <tobias@archlinux.org>
   4
   5 pkgname=ftgl
   6 _pkgver=2.1.3-rc5
   7 pkgver=2.4.0
   8 pkgrel=2
   9 pkgdesc="OpenGL library to use arbitrary fonts"
  10 arch=(x86_64)
  11 url="https://github.com/frankheckenbach/ftgl"
  12 license=(MIT)
  13 depends=(freetype2 glu)
  14 makedepends=(doxygen mesa graphviz git)
  15 _commit=483639219095ad080538e07ceb5996de901d4e74  # tags/v2.4.0
  16 source=("git+https://github.com/frankheckenbach/ftgl#commit=$_commit")
  17 sha256sums=('SKIP')
  18
  19 pkgver() {
  20   cd $pkgname
  21   git describe --tags | sed 's/^v//;s/-/+/g'
  22 }
  23
  24 prepare() {
  25   cd $pkgname
  26   printf '%s\n' >>docs/doxygen.cfg.in \
  27     HAVE_DOT=yes DOT_IMAGE_FORMAT=svg INTERACTIVE_SVG=yes
  28   ./autogen.sh
  29 }
  30
  31 build() {
  32   cd $pkgname
  33   ./configure --prefix=/usr --with-pic --disable-static
  34   make
  35 }
  36
  37 package() {
  38   cd $pkgname
  39   make DESTDIR="$pkgdir" install
  40
  41   # FS#23283: install missing headers for OpenCascade
  42   install -Dt "$pkgdir/usr/include/FTGL" -m644 src/FT{Face,Size}.h
  43
  44   install -Dt "$pkgdir/usr/share/licenses/$pkgname" -m644 COPYING
  45 }
  46
  47 # vim:set sw=2 et: