fuse2/trunk/PKGBUILD

   1 # Contributor: Ronald van Haren <ronald.archlinux.org>
   2 # Contributor: Tom Gundersen <teg@jklm.no>
   3 # Contributor: Mark Rosenstand <mark@archlinux.org>
   4
   5 pkgname=fuse2
   6 pkgver=2.9.9
   7 pkgrel=4
   8 pkgdesc='Interface for userspace programs to export a filesystem to the Linux kernel'
   9 url='https://github.com/libfuse/libfuse'
  10 arch=('x86_64')
  11 license=('GPL2')
  12 depends=('glibc' 'fuse-common')
  13 makedepends=('pkg-config')
  14 provides=(fuse=$pkgver) # TODO: remove it once all packages start to use 'fuse2' name
  15 replaces=('fuse')
  16 conflicts=('fuse')
  17 options=('!emptydirs')
  18 source=(https://github.com/libfuse/libfuse/releases/download/fuse-$pkgver/fuse-$pkgver.tar.gz{,.asc})
  19 sha1sums=('943ba651b14bc4a3c6fd959ed4b8c04f4a59032d'
  20           'SKIP')
  21 sha512sums=('3d82fafd04f2924299bb09d2bb144935fa004a43fb9a6568e2e1cc5a60fded2efa1711029a0d7f12b3e6e4501f7217f2ee3545646d89da8dece083cb390f23e2'
  22             'SKIP')
  23 validpgpkeys=(ED31791B2C5C1613AF388B8AD113FCAC3C4E599F) # Nikolaus Rath <Nikolaus@rath.org>
  24
  25 build() {
  26   cd fuse-$pkgver
  27
  28   UDEV_RULES_PATH=/usr/lib/udev/rules.d MOUNT_FUSE_PATH=/usr/bin ./configure --prefix=/usr --libdir=/usr/lib --enable-lib --enable-util --disable-example
  29   make
  30 }
  31
  32 package() {
  33   cd fuse-$pkgver
  34
  35   make DESTDIR="${pkgdir}" install
  36
  37   # Remove init script in wrong path
  38   # Don't add our own for now, as fusectl fs oopses on 2.6.18
  39   rm -r "${pkgdir}"/etc/init.d
  40
  41   # static device nodes are handled by udev
  42   rm -r "${pkgdir}"/dev
  43 }