fuse3/repos/extra-x86_64/PKGBUILD

   1 # Contributor: Ronald van Haren <ronald.archlinux.org>
   2 # Contributor: Tom Gundersen <teg@jklm.no>
   3 # Contributor: Mark Rosenstand <mark@archlinux.org>
   4
   5 pkgbase=fuse3
   6 pkgname=(fuse-common fuse3)
   7 pkgver=3.14.1
   8 pkgrel=1
   9 pkgdesc='Interface for userspace programs to export a filesystem to the Linux kernel'
  10 url='https://github.com/libfuse/libfuse'
  11 arch=('x86_64')
  12 license=('GPL2')
  13 makedepends=('pkg-config' 'meson' 'udev')
  14 options=('!emptydirs')
  15 source=(https://github.com/libfuse/libfuse/releases/download/fuse-$pkgver/fuse-$pkgver.tar.xz{,.asc})
  16 sha256sums=('126919d72b46b3e0eb58a9c6933a2a50c36f2ea69f61fe9e78bdba9f463ffa20'
  17             'SKIP')
  18 validpgpkeys=(ED31791B2C5C1613AF388B8AD113FCAC3C4E599F) # Nikolaus Rath <Nikolaus@rath.org>
  19
  20 build() {
  21   cd fuse-$pkgver
  22
  23   rm -rf build
  24   meson --prefix=/usr --sbindir=bin -D examples=false . build
  25   cd build
  26   ninja
  27 }
  28
  29 package_fuse-common() {
  30   pkgdesc="Common files for fuse2/3 packages"
  31   backup=(etc/fuse.conf)
  32
  33   install -Dm644 fuse-${pkgver}/util/fuse.conf "${pkgdir}"/etc/fuse.conf
  34 }
  35
  36 package_fuse3() {
  37   depends=('fuse-common' 'glibc')
  38
  39   cd fuse-$pkgver/build
  40
  41   DESTDIR="${pkgdir}" ninja install
  42
  43   rm -r "${pkgdir}"/etc/init.d
  44   rm -r "${pkgdir}"/etc/fuse.conf
  45
  46   # static device nodes are handled by udev
  47   rm -r "${pkgdir}"/dev
  48 }