gcr-4/repos/extra-x86_64/PKGBUILD

   1 # Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
   2 # Contributor: Ionut Biru <ibiru@archlinux.org>
   3
   4 pkgbase=gcr-4
   5 pkgname=(gcr-4 gcr-4-docs)
   6 pkgver=4.1.0
   7 pkgrel=1
   8 pkgdesc="A library for bits of crypto UI and parsing"
   9 url="https://gitlab.gnome.org/GNOME/gcr"
  10 arch=(x86_64)
  11 license=(GPL2)
  12 depends=(
  13   glib2
  14   libgcrypt
  15   libsecret
  16   openssh
  17   p11-kit
  18   systemd
  19 )
  20 makedepends=(
  21   gi-docgen
  22   git
  23   gobject-introspection
  24   gtk4
  25   meson
  26   vala
  27 )
  28 _commit=3376d13fd57215a6a75d83edce0b010c7483342a  # tags/4.1.0^0
  29 source=("git+https://gitlab.gnome.org/GNOME/gcr.git#commit=$_commit")
  30 b2sums=('SKIP')
  31
  32 pkgver() {
  33   cd gcr
  34   git describe --tags | sed 's/[^-]*-g/r&/;s/-/+/g'
  35 }
  36
  37 prepare() {
  38   cd gcr
  39 }
  40
  41 build() {
  42   arch-meson gcr build
  43   meson compile -C build
  44 }
  45
  46 check() {
  47   # Secure memory tests fail
  48   dbus-run-session meson test -C build --print-errorlogs || :
  49 }
  50
  51 package_gcr-4() {
  52   optdepends=('gtk4: gcr-viewer-gtk4')
  53   provides=(
  54     libgck-2.so
  55     libgcr-4.so
  56   )
  57   install=gcr-4.install
  58
  59   meson install -C build --destdir "$pkgdir"
  60
  61   mkdir -p doc/usr/share
  62   mv {"$pkgdir",doc}/usr/share/doc
  63 }
  64
  65 package_gcr-4-docs() {
  66   pkgdesc+=" (documentation)"
  67   depends=()
  68
  69   mv doc/* "$pkgdir"
  70 }
  71
  72 # vim:set sw=2 sts=-1 et: