gcr/repos/extra-x86_64/PKGBUILD

   1 # Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
   2 # Contributor: Ionut Biru <ibiru@archlinux.org>
   3
   4 pkgbase=gcr
   5 pkgname=(gcr gcr-docs)
   6 pkgver=3.41.1
   7 pkgrel=4
   8 pkgdesc="A library for bits of crypto UI and parsing"
   9 url="https://gitlab.gnome.org/GNOME/gcr"
  10 arch=(x86_64)
  11 license=(GPL2)
  12 depends=(
  13   gtk3
  14   libgcrypt
  15   libsecret
  16   openssh
  17   p11-kit
  18 )
  19 makedepends=(
  20   gi-docgen
  21   git
  22   gobject-introspection
  23   libxslt
  24   meson
  25   vala
  26 )
  27 _commit=664f8d8619cc6d661bd863107824efbac383a9bf  # tags/3.41.1^0
  28 source=("git+https://gitlab.gnome.org/GNOME/gcr.git#commit=$_commit")
  29 b2sums=('SKIP')
  30
  31 pkgver() {
  32   cd gcr
  33   git describe --tags | sed 's/[^-]*-g/r&/;s/-/+/g'
  34 }
  35
  36 prepare() {
  37   cd gcr
  38 }
  39
  40 build() {
  41   # ssh-agent moved to gcr-4
  42   arch-meson gcr build -D ssh_agent=false
  43   meson compile -C build
  44 }
  45
  46 check() {
  47   # Secure memory tests fail
  48   dbus-run-session meson test -C build --print-errorlogs || :
  49 }
  50
  51 package_gcr() {
  52   provides=(
  53     libgck-1.so
  54     libgcr-{base,ui}-3.so
  55   )
  56   install=gcr.install
  57
  58   meson install -C build --destdir "$pkgdir"
  59
  60   mkdir -p doc/usr/share
  61   mv {"$pkgdir",doc}/usr/share/doc
  62 }
  63
  64 package_gcr-docs() {
  65   pkgdesc+=" (documentation)"
  66   depends=()
  67
  68   mv doc/* "$pkgdir"
  69 }
  70
  71 # vim:set sw=2 sts=-1 et: