ghex/repos/extra-x86_64/PKGBUILD

   1 # Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
   2 # Contributor: Jan de Groot <jgc@archlinux.org>
   3 # Contributor: Tobias Kieslich <tobias@justdreams.de>
   4
   5 pkgbase=ghex
   6 pkgname=(
   7   ghex
   8   ghex-docs
   9 )
  10 pkgver=44.1
  11 pkgrel=1
  12 pkgdesc="A simple binary editor for the Gnome desktop"
  13 url="https://wiki.gnome.org/Apps/Ghex"
  14 arch=(x86_64)
  15 license=(GPL)
  16 depends=(libadwaita)
  17 makedepends=(
  18   gi-docgen
  19   git
  20   gobject-introspection
  21   meson
  22   yelp-tools
  23 )
  24 _commit=128561d95b1d5088a27d5ad4ebe7bab265437d7a  # tags/44.1^0
  25 source=("git+https://gitlab.gnome.org/GNOME/ghex.git#commit=$_commit")
  26 b2sums=('SKIP')
  27
  28 pkgver() {
  29   cd ghex
  30   git describe --tags | sed 's/[^-]*-g/r&/;s/-/+/g'
  31 }
  32
  33 prepare() {
  34   cd ghex
  35 }
  36
  37 build() {
  38   arch-meson ghex build -D gtk_doc=true
  39   meson compile -C build
  40 }
  41
  42 check() {
  43   meson test -C build --print-errorlogs
  44 }
  45
  46 package_ghex() {
  47   provides=(libgtkhex-4.so)
  48   groups=(gnome-extra)
  49
  50   meson install -C build --destdir "$pkgdir"
  51
  52   mkdir -p doc/usr/share
  53   mv {"$pkgdir",doc}/usr/share/doc
  54 }
  55
  56 package_ghex-docs() {
  57   pkgdesc+=" (documentation)"
  58   depends=()
  59
  60   mv doc/* "$pkgdir"
  61 }
  62
  63 # vim:set sw=2 sts=-1 et: