gnome-devel-docs/repos/extra-any/PKGBUILD

   1 # Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
   2 # Contributor: Jan de Groot <jgc@archlinux.org>
   3
   4 pkgname=gnome-devel-docs
   5 pkgver=40.3
   6 pkgrel=1
   7 pkgdesc="Developer documentation for GNOME"
   8 url="https://gitlab.gnome.org/GNOME/gnome-devel-docs"
   9 arch=(any)
  10 license=(FDL)
  11 depends=(yelp)
  12 makedepends=(yelp-tools git)
  13 groups=(gnome-extra)
  14 _commit=6032dcd16a893c9e6463af9a3b0f0e505d0ce1ce  # tags/40.3^0
  15 source=("git+https://gitlab.gnome.org/GNOME/gnome-devel-docs.git#commit=$_commit")
  16 sha256sums=('SKIP')
  17
  18 pkgver() {
  19   cd $pkgname
  20   git describe --tags | sed 's/-/+/g'
  21 }
  22
  23 prepare() {
  24   cd $pkgname
  25   autoreconf -fvi
  26 }
  27
  28 build() {
  29   cd $pkgname
  30   ./configure --prefix=/usr --sysconfdir=/etc --localstatedir=/var
  31   make
  32 }
  33
  34 package() {
  35   cd $pkgname
  36   make DESTDIR="$pkgdir" install
  37 }