gnome-disk-utility/repos/extra-x86_64/PKGBUILD

   1 # Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
   2 # Contributor: Jan de Groot <jgc@archlinux.org>
   3 # Contributor: Silvio Knizek (killermoehre)
   4
   5 pkgname=gnome-disk-utility
   6 pkgver=44.0
   7 pkgrel=1
   8 pkgdesc="Disk Management Utility for GNOME"
   9 url="https://gitlab.gnome.org/GNOME/gnome-disk-utility"
  10 arch=(x86_64)
  11 license=(GPL)
  12 depends=(
  13   gtk3
  14   libcanberra
  15   libdvdread
  16   libhandy
  17   libnotify
  18   libpwquality
  19   libsecret
  20   parted
  21   systemd
  22   udisks2
  23 )
  24 makedepends=(
  25   docbook-xsl
  26   git
  27   meson
  28 )
  29 groups=(gnome)
  30 _commit=68c13081e29973b31ee37245626b1755b8cd53a6  # tags/44.0^0
  31 source=("git+https://gitlab.gnome.org/GNOME/gnome-disk-utility.git#commit=$_commit")
  32 sha256sums=('SKIP')
  33
  34 pkgver() {
  35   cd $pkgname
  36   git describe --tags | sed 's/[^-]*-g/r&/;s/-/+/g'
  37 }
  38
  39 build() {
  40   arch-meson $pkgname build
  41   meson compile -C build
  42 }
  43
  44 check() {
  45   meson test -C build --print-errorlogs
  46 }
  47
  48 package() {
  49   meson install -C build --destdir "$pkgdir"
  50 }
  51
  52 # vim:set sw=2 sts=-1 et: