gnome-menus/repos/extra-x86_64/PKGBUILD

   1 # Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
   2 # Contributor: Jan de Groot <jan@archlinux.org>
   3
   4 pkgname=gnome-menus
   5 pkgver=3.36.0
   6 pkgrel=2
   7 pkgdesc="GNOME menu specifications"
   8 url="https://gitlab.gnome.org/GNOME/gnome-menus"
   9 arch=(x86_64)
  10 license=(GPL LGPL)
  11 groups=(gnome)
  12 depends=(glib2)
  13 makedepends=(intltool gobject-introspection git gnome-common)
  14 provides=(libgnome-menu-3.so)
  15 options=(debug)
  16 _commit=66ac7579856968d3f4b76c04d55327c60b37f2fb  # tags/3.36.0^0
  17 source=("git+https://gitlab.gnome.org/GNOME/gnome-menus.git#commit=$_commit")
  18 sha256sums=('SKIP')
  19
  20 pkgver() {
  21   cd $pkgname
  22   git describe --tags | sed 's/[^-]*-g/r&/;s/-/+/g'
  23 }
  24
  25 prepare() {
  26   cd $pkgname
  27   NOCONFIGURE=1 ./autogen.sh
  28 }
  29
  30 build() {
  31   cd $pkgname
  32   ./configure --prefix=/usr --sysconfdir=/etc --localstatedir=/var \
  33     --disable-static
  34   sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
  35   make
  36 }
  37
  38 check() {
  39   cd $pkgname
  40   make check
  41 }
  42
  43 package(){
  44   cd $pkgname
  45   make DESTDIR="$pkgdir" install
  46 }