gnome-music/repos/extra-any/PKGBUILD

   1 # Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
   2 # Contributor: Jan de Groot <jgc@archlinux.org>
   3
   4 pkgname=gnome-music
   5 pkgver=44.0
   6 pkgrel=2
   7 epoch=1
   8 pkgdesc="Music player and management application"
   9 url="https://wiki.gnome.org/Apps/Music"
  10 arch=(any)
  11 license=(GPL)
  12 depends=(
  13   grilo
  14   grilo-plugins
  15   gst-plugins-base
  16   gst-plugins-good
  17   gtk4
  18   libadwaita
  19   libmediaart
  20   python-cairo
  21   python-gobject
  22   tracker3-miners
  23 )
  24 makedepends=(
  25   appstream-glib
  26   git
  27   gobject-introspection
  28   meson
  29   yelp-tools
  30 )
  31 optdepends=(
  32   'gst-libav: Extra media codecs'
  33   'gst-plugins-bad: Extra media codecs'
  34   'gst-plugins-ugly: Extra media codecs'
  35 )
  36 groups=(gnome)
  37 _commit=11fa1a75fc1377a4afdbffe60c8890fdfe713a3f  # tags/44.0^0
  38 source=("git+https://gitlab.gnome.org/GNOME/gnome-music.git#commit=$_commit")
  39 b2sums=('SKIP')
  40
  41 pkgver() {
  42   cd $pkgname
  43   git describe --tags | sed 's/[^-]*-g/r&/;s/-/+/g'
  44 }
  45
  46 prepare() {
  47   cd $pkgname
  48 }
  49
  50 build() {
  51   arch-meson $pkgname build
  52   meson compile -C build
  53 }
  54
  55 check() {
  56   meson test -C build --print-errorlogs
  57 }
  58
  59 package() {
  60   meson install -C build --destdir "$pkgdir"
  61
  62   python -m compileall -d /usr/lib "$pkgdir/usr/lib"
  63   python -O -m compileall -d /usr/lib "$pkgdir/usr/lib"
  64 }
  65
  66 # vim:set sw=2 sts=-1 et: