gnumeric/trunk/PKGBUILD

   1 # Maintainer: Eric Belanger <eric@archlinux.org>
   2 # Contributor: Kritoke <typeolinux@yahoo.com>
   3
   4 pkgname=gnumeric
   5 pkgver=1.12.55
   6 pkgrel=2
   7 pkgdesc="A GNOME Spreadsheet Program"
   8 arch=('x86_64')
   9 url="http://www.gnumeric.org/"
  10 license=('GPL')
  11 depends=('goffice')
  12 makedepends=('intltool' 'psiconv' 'pygobject-devel' docbook-xml
  13              'gobject-introspection' 'python-gobject' gtk-doc autoconf-archive git yelp-tools)
  14 optdepends=('python-gobject: for python plugin support'
  15             'perl: for perl plugin support'
  16             'psiconv: for Psion 5 file support'
  17             'yelp: for viewing the help manual')
  18 _commit=aea59b387be8bd5dc509ba75820cd9377e1e34a7
  19 source=("git+https://gitlab.gnome.org/GNOME/gnumeric.git#commit=$_commit"
  20         revert-warnings.patch)
  21 sha256sums=('SKIP'
  22             'bcafca016b809000c2a5bf911e2e3dfa4de28f9e541d9964574cac5c7ce09e53')
  23
  24 pkgver() {
  25   cd $pkgname
  26   git describe --tags | sed 's/^GNUMERIC_//;s/_/./g;s/-/+/g'
  27 }
  28
  29 prepare() {
  30   cd $pkgname
  31   patch -Np0 -i ../revert-warnings.patch
  32   NOCONFIGURE=1 ./autogen.sh
  33 }
  34
  35 build() {
  36   cd $pkgname
  37   ./configure --prefix=/usr --sysconfdir=/etc --localstatedir=/var \
  38     --disable-schemas-compile --enable-introspection --disable-silent-rules
  39
  40   sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
  41   make
  42 }
  43
  44 package() {
  45   cd $pkgname
  46   make DESTDIR="${pkgdir}" install
  47 }