gsettings-desktop-schemas/repos/extra-any/PKGBUILD

   1 # Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
   2 # Contributor: Ionut Biru <ibiru@archlinux.org>
   3 # Contributor: Jaroslav Lichtblau <dragonlord@aur.archlinux.org>
   4 # Contributor: Adam Hani Schakaki (krzd) <krzd@krzd.net>
   5
   6 pkgname=gsettings-desktop-schemas
   7 pkgver=44.0
   8 pkgrel=1
   9 pkgdesc="Shared GSettings schemas for the desktop"
  10 url="https://gitlab.gnome.org/GNOME/gsettings-desktop-schemas"
  11 arch=(any)
  12 license=(GPL)
  13 depends=(
  14   adobe-source-code-pro-fonts
  15   cantarell-fonts
  16   dconf
  17   glib2
  18 )
  19 makedepends=(
  20   git
  21   gobject-introspection
  22   meson
  23 )
  24 _commit=eff0b3609ff745fcb58cba7198397c642702736e  # tags/44.0^0
  25 source=("git+https://gitlab.gnome.org/GNOME/gsettings-desktop-schemas.git#commit=$_commit")
  26 b2sums=('SKIP')
  27
  28 pkgver() {
  29   cd $pkgname
  30   git describe --tags | sed 's/[^-]*-g/r&/;s/-/+/g'
  31 }
  32
  33 prepare() {
  34   cd $pkgname
  35 }
  36
  37 build() {
  38   arch-meson $pkgname build
  39   meson compile -C build
  40 }
  41
  42 check() {
  43   meson test -C build --print-errorlogs
  44 }
  45
  46 package() {
  47   meson install -C build --destdir "$pkgdir"
  48 }
  49
  50 # vim:set sw=2 sts=-1 et: