gsound/trunk/PKGBUILD

   1 # Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
   2 # Contributor: Jan de Groot <jgc@archlinux.org>
   3
   4 pkgname=gsound
   5 pkgver=1.0.3
   6 pkgrel=2
   7 pkgdesc="Small library for playing system sounds"
   8 url="https://wiki.gnome.org/Projects/GSound"
   9 license=(LGPL)
  10 arch=(x86_64)
  11 depends=(glib2 libcanberra)
  12 makedepends=(gobject-introspection vala git gtk-doc meson)
  13 _commit=95d36d60cf53e0e7c5d5325e0f1f4fc765a611ae  # tags/1.0.3^0
  14 source=("git+https://gitlab.gnome.org/GNOME/gsound.git#commit=$_commit")
  15 sha256sums=('SKIP')
  16
  17 pkgver() {
  18   cd gsound
  19   git describe --tags | sed 's/[^-]*-g/r&/;s/-/+/g'
  20 }
  21
  22 prepare() {
  23   cd gsound
  24 }
  25
  26 build() {
  27   arch-meson gsound build -D gtk_doc=true
  28   meson compile -C build
  29 }
  30
  31 check() {
  32   meson test -C build --print-errorlogs
  33 }
  34
  35 package() {
  36   depends+=(libg{lib,object,io}-2.0.so libcanberra.so)
  37   provides+=(libgsound.so)
  38
  39   meson install -C build --destdir "$pkgdir"
  40 }