gtk-doc/repos/extra-any/PKGBUILD

   1 # Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
   2 # Contributor: Jan de Groot <jgc@archlinux.org>
   3
   4 pkgname=gtk-doc
   5 pkgver=1.33.2
   6 pkgrel=1
   7 pkgdesc="Documentation tool for public library API"
   8 url="https://www.gtk.org/gtk-doc/"
   9 arch=(any)
  10 license=(GPL FDL)
  11 depends=(docbook-xsl docbook-xml glib2-docs python-lxml python-pygments
  12          python-anytree)
  13 makedepends=(dblatex git yelp-tools meson)
  14 checkdepends=(bc gtk3 python-six python-parameterized)
  15 optdepends=('dblatex: PDF support')
  16 _commit=14391142ee9d43da116f0f530746ae34cc46930a  # tags/1.33.2^0
  17 source=("git+https://gitlab.gnome.org/GNOME/gtk-doc.git#commit=$_commit"
  18         fix.diff)
  19 sha256sums=('SKIP'
  20             '120d6d92fe2040b3500fee17a9c52e3f427cec70637d7aa71dbd561226103237')
  21
  22 pkgver() {
  23   cd $pkgname
  24   git describe --tags | sed 's/GTK_DOC_//;s/_/\./g;s/-/+/g'
  25 }
  26
  27 prepare() {
  28   cd $pkgname
  29   patch -Np1 -i ../fix.diff
  30 }
  31
  32 build() {
  33   arch-meson $pkgname build
  34   meson compile -C build
  35 }
  36
  37 check() {
  38   meson test -C build --print-errorlogs
  39 }
  40
  41 package() {
  42   DESTDIR="$pkgdir" meson install -C build
  43   python -m compileall -d /usr/lib "$pkgdir/usr/lib"
  44   python -O -m compileall -d /usr/lib "$pkgdir/usr/lib"
  45 }