gtk-vnc/repos/extra-x86_64/PKGBUILD

   1 # Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
   2 # Contributor: Jan de Groot <jgc@archlinux.org>
   3 # Contributor: Allan McRae <mcrae_allan@hotmail.com>
   4 # Contributor: lp76 <l.peduto@gmail.com>
   5
   6 pkgname=gtk-vnc
   7 pkgver=1.3.1
   8 pkgrel=1
   9 pkgdesc="VNC viewer widget for GTK"
  10 url="https://wiki.gnome.org/Projects/gtk-vnc"
  11 arch=(x86_64)
  12 license=(LGPL)
  13 depends=(libgcrypt gtk3 gnutls libpulse)
  14 makedepends=(vala gobject-introspection git perl-text-csv meson)
  15 provides=(libgtk-vnc-2.0.so libgvnc{,pulse}-1.0.so)
  16 options=(debug)
  17 _commit=1ea35aa11bdf97916409504024bcd36a01abc64d  # tags/v1.3.1^0
  18 source=("git+https://gitlab.gnome.org/GNOME/gtk-vnc.git#commit=$_commit"
  19         "git+https://gitlab.com/keycodemap/keycodemapdb.git")
  20 sha256sums=('SKIP'
  21             'SKIP')
  22
  23 pkgver() {
  24   cd gtk-vnc
  25   git describe --tags | sed 's/^v//;s/[^-]*-g/r&/;s/-/+/g'
  26 }
  27
  28 prepare() {
  29   cd gtk-vnc
  30
  31   git submodule init
  32   git submodule set-url src/keycodemapdb "$srcdir/keycodemapdb"
  33   git submodule update
  34 }
  35
  36 build() {
  37   arch-meson gtk-vnc build
  38   meson compile -C build
  39 }
  40
  41 check() {
  42   meson test -C build --print-errorlogs
  43 }
  44
  45 package() {
  46   meson install -C build --destdir "$pkgdir"
  47   install -Dt "$pkgdir/usr/bin" build/examples/gvncviewer
  48 }