gtk-vnc/trunk/PKGBUILD

   1 # Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
   2 # Contributor: Jan de Groot <jgc@archlinux.org>
   3 # Contributor: Allan McRae <mcrae_allan@hotmail.com>
   4 # Contributor: lp76 <l.peduto@gmail.com>
   5
   6 pkgname=gtk-vnc
   7 pkgver=1.3.1
   8 pkgrel=1
   9 pkgdesc="VNC viewer widget for GTK"
  10 url="https://wiki.gnome.org/Projects/gtk-vnc"
  11 arch=(x86_64)
  12 license=(LGPL)
  13 depends=(libgcrypt gtk3 gnutls libpulse)
  14 makedepends=(vala gobject-introspection git perl-text-csv meson)
  15 provides=(libgtk-vnc-2.0.so libgvnc{,pulse}-1.0.so)
  16 _commit=1ea35aa11bdf97916409504024bcd36a01abc64d  # tags/v1.3.1^0
  17 source=("git+https://gitlab.gnome.org/GNOME/gtk-vnc.git#commit=$_commit"
  18         "git+https://gitlab.com/keycodemap/keycodemapdb.git")
  19 sha256sums=('SKIP'
  20             'SKIP')
  21
  22 pkgver() {
  23   cd gtk-vnc
  24   git describe --tags | sed 's/^v//;s/[^-]*-g/r&/;s/-/+/g'
  25 }
  26
  27 prepare() {
  28   cd gtk-vnc
  29
  30   git submodule init
  31   git submodule set-url src/keycodemapdb "$srcdir/keycodemapdb"
  32   git submodule update
  33 }
  34
  35 build() {
  36   arch-meson gtk-vnc build
  37   meson compile -C build
  38 }
  39
  40 check() {
  41   meson test -C build --print-errorlogs
  42 }
  43
  44 package() {
  45   meson install -C build --destdir "$pkgdir"
  46   install -Dt "$pkgdir/usr/bin" build/examples/gvncviewer
  47 }