gtkmm3/repos/extra-x86_64/PKGBUILD

   1 # Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
   2 # Contributor: Ionut Biru <ibiru@archlinux.org>
   3
   4 pkgbase=gtkmm3
   5 pkgname=(gtkmm3 gtkmm3-docs)
   6 pkgver=3.24.7
   7 pkgrel=1
   8 pkgdesc="C++ bindings for GTK+ 3"
   9 url="https://www.gtkmm.org/"
  10 arch=(x86_64)
  11 license=(LGPL)
  12 depends=(gtk3 pangomm atkmm)
  13 makedepends=(git meson mm-common glibmm-docs cairomm-docs pangomm-docs
  14              atkmm-docs)
  15 checkdepends=(xorg-server-xvfb)
  16 options=(!emptydirs debug)
  17 _commit=d8bd947d97684bfd351552b962bdc79d04c0f24d  # tags/3.24.7^0
  18 source=("git+https://gitlab.gnome.org/GNOME/gtkmm.git#commit=$_commit")
  19 sha256sums=('SKIP')
  20
  21 pkgver() {
  22   cd gtkmm
  23   git describe --tags | sed 's/[^-]*-g/r&/;s/-/+/g'
  24 }
  25
  26 prepare() {
  27   cd gtkmm
  28 }
  29
  30 build() {
  31   arch-meson gtkmm build -D maintainer-mode=true
  32   meson compile -C build
  33 }
  34
  35 check() {
  36   xvfb-run -s '-nolisten local' meson test -C build --print-errorlogs
  37 }
  38
  39 package_gtkmm3() {
  40   depends+=(libsigc-2.0.so libglibmm-2.4.so libcairomm-1.0.so libpangomm-1.4.so
  41             libatkmm-1.6.so)
  42   provides=(libgtkmm-3.0.so)
  43
  44   meson install -C build --destdir "$pkgdir"
  45
  46   # Split -docs
  47   mkdir -p docs/usr/share
  48   mv -t docs/usr/share "$pkgdir"/usr/share/{devhelp,doc}
  49 }
  50
  51 package_gtkmm3-docs() {
  52   pkgdesc+=" (documentation)"
  53   depends=()
  54   options=(!strip)
  55
  56   mv -t "$pkgdir" docs/*
  57 }