hwloc/trunk/PKGBUILD

   1 # Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
   2 # Contributor: Stéphane Gaudreault <stephane@archlinux.org>
   3 # Contributor: Sylvain HENRY <hsyl20@yahoo.fr>
   4 # Contributor: Hervé YVIQUEL <elldekaa@gmail.com>
   5
   6 pkgname=hwloc
   7 pkgver=2.9.1
   8 pkgrel=1
   9 pkgdesc='Portable Hardware Locality is a portable abstraction of hierarchical architectures'
  10 url='https://www.open-mpi.org/projects/hwloc/'
  11 arch=('x86_64')
  12 license=('BSD')
  13 depends=('glibc' 'libtool' 'systemd-libs' 'libpciaccess')
  14 makedepends=('cairo' 'libxml2' 'pciutils' 'systemd' 'libx11')
  15 optdepends=('cairo' 'libxml2' 'pciutils' 'libx11')
  16 options=('!docs')
  17 source=(https://www.open-mpi.org/software/hwloc/v${pkgver%.*}/downloads/${pkgname}-${pkgver}.tar.bz2)
  18 sha512sums=('9c05b7b7c4e3cb5474efb6eb1a4bf3e5ad0f8d0480d043a11e695e4a1f5f6748abb96c7055c0f3b2bc36950dda247fbdd7dc02ec7c9debbfe2631e6ebb89d957')
  19 b2sums=('6f0a0caa593683d76b52751b32d47a28509fc99e9ee4b8645257de054823328afe35e46ac5e264a8a6a9279e6c06129d6df096b7c2c491d90fc7d05ee0c011f5')
  20
  21 build() {
  22   cd hwloc-${pkgver}
  23   ./configure \
  24     --prefix=/usr \
  25     --sbindir=/usr/bin \
  26     --enable-plugins \
  27     --sysconfdir=/etc
  28   make
  29 }
  30
  31 check() {
  32   cd hwloc-${pkgver}
  33   make check
  34 }
  35
  36 package() {
  37   cd hwloc-${pkgver}
  38   make DESTDIR="${pkgdir}" install
  39   install -Dm 644 COPYING -t "${pkgdir}/usr/share/licenses/${pkgname}"
  40 }
  41
  42 # vim: ts=2 sw=2 et: