kate/repos/extra-x86_64/PKGBUILD

   1 # Maintainer: Felix Yan <felixonmars@archlinux.org>
   2 # Maintainer: Antonio Rojas <arojas@archlinux.org>
   3 # Contributor: Andrea Scarpino <andrea@archlinux.org>
   4
   5 pkgname=kate
   6 pkgver=23.04.1
   7 pkgrel=1
   8 arch=(x86_64)
   9 license=(GPL LGPL FDL)
  10 pkgdesc='Advanced text editor'
  11 groups=(kde-applications kde-utilities)
  12 url='https://apps.kde.org/kate/'
  13 depends=(knewstuff ktexteditor kactivities kuserfeedback hicolor-icon-theme)
  14 optdepends=('konsole: open a terminal in Kate'
  15             'clang: C and C++ LSP support'
  16             'python-lsp-server: Python LSP support'
  17             'texlab: LaTeX LSP support'
  18             'rust: Rust LSP support'
  19             'git: git-blame plugin'
  20             'markdownpart: Markdown preview'
  21             'svgpart: SVG preview')
  22 makedepends=(extra-cmake-modules kdoctools)
  23 conflicts=(kwrite)
  24 provides=(kwrite)
  25 replaces=(kwrite)
  26 source=(https://download.kde.org/stable/release-service/$pkgver/src/$pkgname-$pkgver.tar.xz{,.sig})
  27 sha256sums=('5c384b0fe9706840e4064c71a45069b80da0448c11bfa2debf9dd5953b8e17f0'
  28             'SKIP')
  29 validpgpkeys=(CA262C6C83DE4D2FB28A332A3A6A4DB839EAA6D7  # Albert Astals Cid <aacid@kde.org>
  30               F23275E4BF10AFC1DF6914A6DBD2CE893E2D1C87  # Christoph Feck <cfeck@kde.org>
  31               D81C0CB38EB725EF6691C385BB463350D6EF31EF) # Heiko Becker <heiko.becker@kde.org>
  32
  33 build() {
  34   cmake -B build -S $pkgname-$pkgver \
  35     -DBUILD_TESTING=OFF
  36   cmake --build build
  37 }
  38
  39 package() {
  40   DESTDIR="$pkgdir" cmake --install build
  41 }