kpat/trunk/PKGBUILD

   1 # Maintainer: Felix Yan <felixonmars@archlinux.org>
   2 # Maintainer: Antonio Rojas <arojas@archlinux.org>
   3 # Contributor: Andrea Scarpino <andrea@archlinux.org>
   4
   5 pkgname=kpat
   6 pkgver=23.04.1
   7 pkgrel=1
   8 pkgdesc='Offers a selection of solitaire card games'
   9 url='https://apps.kde.org/kpat/'
  10 arch=(x86_64)
  11 license=(GPL LGPL FDL)
  12 groups=(kde-applications kde-games)
  13 depends=(libkdegames freecell-solver black-hole-solver hicolor-icon-theme)
  14 makedepends=(extra-cmake-modules kdoctools)
  15 conflicts=(kpatience)
  16 replaces=(kpatience)
  17 source=(https://download.kde.org/stable/release-service/$pkgver/src/$pkgname-$pkgver.tar.xz{,.sig})
  18 sha256sums=('650f21b43b3b27dcaa8684dfd4cca09485cfcce65b0f444871e4c782e3cbc180'
  19             'SKIP')
  20 validpgpkeys=(CA262C6C83DE4D2FB28A332A3A6A4DB839EAA6D7  # Albert Astals Cid <aacid@kde.org>
  21               F23275E4BF10AFC1DF6914A6DBD2CE893E2D1C87  # Christoph Feck <cfeck@kde.org>
  22               D81C0CB38EB725EF6691C385BB463350D6EF31EF) # Heiko Becker <heiko.becker@kde.org>
  23
  24 build() {
  25   cmake -B build -S $pkgname-$pkgver \
  26     -DBUILD_TESTING=OFF
  27   cmake --build build
  28 }
  29
  30 package() {
  31   DESTDIR="$pkgdir" cmake --install build
  32 }