latex2rtf/trunk/PKGBUILD

   1 # Maintainer: Rémy Oudompheng <remy@archlinux.org>
   2 # Contributor: John Proctor <jproctor@prium.net>
   3
   4 pkgname=latex2rtf
   5 pkgver=2.3.18
   6 pkgrel=1
   7 pkgdesc="LaTeX to RTF converter"
   8 arch=('x86_64')
   9 url="http://latex2rtf.sourceforge.net/"
  10 license=('GPL')
  11 depends=('glibc' 'imagemagick' 'ghostscript')
  12 makedepends=('texinfo' 'texlive-bin' 'texlive-plainextra')
  13 checkdepends=('texlive-latexextra') # for a4wide package
  14 source=("https://downloads.sourceforge.net/sourceforge/${pkgname}/${pkgname}-${pkgver}a.tar.gz")
  15 md5sums=('b984073a9481eae26760ce03015d0373')
  16 sha1sums=('7fe41c82465921405bbbc6667694bf2731c7dfd1')
  17 sha512sums=('b6caef616e8e63e8779a86dae6cbe0993de5421bd6700fe9118bee2af528c496c0e849ae5315ed6fc86be6c7fbe7fa073e41b39e8c5da2da4e65b26784135589')
  18
  19 build() {
  20   cd "${srcdir}/${pkgname}-${pkgver}"
  21   make PREFIX=/usr latex2rtf
  22 }
  23
  24 check() {
  25   cd "${srcdir}/${pkgname}-${pkgver}"
  26   sed -i 's,s/\\\\,s/\\\\\\,' test/bracecheck
  27   chmod u+x test/bracecheck
  28   RTFPATH="$PWD"/cfg make check
  29 }
  30
  31 package() {
  32   cd "${srcdir}/${pkgname}-${pkgver}"
  33   make DESTDIR="${pkgdir}" PREFIX=/usr install install-info
  34   chmod 755 "${pkgdir}/usr/bin/latex2png"
  35   sed -i -e 's|error "no input file specified"| echo "error: no input file specified"|' "${pkgdir}/usr/bin/latex2png"
  36 }