lib2geom/trunk/PKGBUILD

   1 # Maintainer: Christian Hesse <mail@eworm.de>
   2
   3 pkgname=lib2geom
   4 pkgver=1.2.2
   5 pkgrel=2
   6 pkgdesc='Easy to use 2D geometry library in C++'
   7 arch=('x86_64')
   8 url='https://gitlab.com/inkscape/lib2geom'
   9 license=('GPL')
  10 depends=('glib2' 'gsl' 'double-conversion' 'cairo' 'ragel')
  11 makedepends=('cmake' 'boost' 'gtest')
  12 source=("https://gitlab.com/inkscape/${pkgname}/-/archive/${pkgver}/${pkgname}-${pkgver}.tar.bz2")
  13 sha256sums=('1c22a7be571d2e2f3ee98424614ffd6a42fe73dedbd2ccfb0967ecb02f77edeb')
  14
  15 build() {
  16   cd "${srcdir}/${pkgname}-${pkgver}"
  17
  18   mkdir -p build
  19   cd build
  20   cmake .. \
  21     -DCMAKE_INSTALL_PREFIX=/usr \
  22     -D2GEOM_BOOST_PYTHON=NO \
  23     -D2GEOM_BUILD_SHARED=YES \
  24     -DCMAKE_BUILD_TYPE=Release
  25   make
  26 }
  27
  28 check() {
  29   cd "${srcdir}/${pkgname}-${pkgver}/build/"
  30
  31   make test
  32 }
  33
  34 package() {
  35   cd "${srcdir}/${pkgname}-${pkgver}/build/"
  36
  37   make DESTDIR="${pkgdir}/" install
  38 }