libbsd/trunk/PKGBUILD

   1 # Maintainer: Lukas Fleischer <lfleischer@archlinux.org>
   2 # Contributor: Sven-Hendrik Haase <sh@lutzhaase.com>
   3 # Contributor: Gerardo Exequiel Pozzi <vmlinuz386@yahoo.com.ar>
   4
   5 pkgname=libbsd
   6 pkgver=0.11.7
   7 pkgrel=1
   8 pkgdesc='Provides useful functions commonly found on BSD systems like strlcpy()'
   9 arch=('x86_64')
  10 url="https://libbsd.freedesktop.org"
  11 license=('custom')
  12 depends=('glibc' 'libmd')
  13 options=('staticlibs')
  14 source=("https://libbsd.freedesktop.org/releases/$pkgname-$pkgver.tar.xz"{,.asc})
  15 sha512sums=('51fda4724f41dd8a4628afd58c21236a7588d9045e337e06eeabf83805a9aaaa53705441ca901ad11f1c65f18e881523bdc97721a7d3d6a5cced27f2450d09a2'
  16             'SKIP')
  17 validpgpkeys=('4F3E74F436050C10F5696574B972BF3EA4AE57A3') # Guillem Jover
  18
  19 build() {
  20   cd "$pkgname-$pkgver"
  21
  22   CFLAGS+=' -ffat-lto-objects' \
  23   ./configure --prefix=/usr
  24   make
  25 }
  26
  27 check() {
  28   cd "$pkgname-$pkgver"
  29   make check
  30 }
  31
  32 package() {
  33   cd "$pkgname-$pkgver"
  34
  35   make DESTDIR="$pkgdir" install
  36   rm "${pkgdir}"/usr/lib/libbsd.a
  37   install -D -m644 COPYING "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
  38
  39   # included now in man-pages, FS#53351
  40   rm -f "${pkgdir}"/usr/share/man/man3/explicit_bzero.3
  41 }