libffi/repos/core-x86_64/PKGBUILD

   1 # Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
   2 # Contributor: Bartłomiej Piotrowski <bpiotrowski@archlinux.org>
   3 # Contributor: Stéphane Gaudreault <stephane@archlinux.org>
   4 # Contributor: Jan de Groot <jgc@archlinux.org>
   5
   6 pkgname=libffi
   7 pkgver=3.4.4
   8 pkgrel=1
   9 pkgdesc='Portable foreign function interface library'
  10 arch=('x86_64')
  11 url='https://sourceware.org/libffi/'
  12 license=('MIT')
  13 depends=('glibc')
  14 checkdepends=('dejagnu')
  15 provides=('libffi.so')
  16 options=('debug')
  17 source=(https://github.com/libffi/libffi/releases/download/v$pkgver/libffi-$pkgver.tar.gz)
  18 sha256sums=('d66c56ad259a82cf2a9dfc408b32bf5da52371500b84745f7fb8b645712df676')
  19 b2sums=('189fe1ffe9507f204581b0ab09995dc7e7b761bb4eac7e338e9f5ff81431aebcef6c182c1839c9f9acb2706697a260c67e6d1351cf7e2aed7c4eb5d694f6f8fd')
  20
  21 build() {
  22   cd $pkgname-$pkgver
  23   # remove --disable-exec-static-tramp once ghc and gobject-introspection
  24   # work fine with it enabled (https://github.com/libffi/libffi/pull/647)
  25   ./configure \
  26     --prefix=/usr \
  27     --disable-static \
  28     --disable-multi-os-directory \
  29     --disable-exec-static-tramp \
  30     --enable-pax_emutramp
  31   make
  32 }
  33
  34 check() {
  35   make -C $pkgname-$pkgver check
  36 }
  37
  38 package() {
  39   cd $pkgname-$pkgver
  40   make DESTDIR="$pkgdir" install
  41   install -Dm 644 LICENSE -t "$pkgdir"/usr/share/licenses/$pkgname
  42   install -Dm 644 README.md -t "$pkgdir"/usr/share/doc/$pkgname
  43 }
  44
  45 # vim:set ts=2 sw=2 et: