libfprint/repos/extra-x86_64/PKGBUILD

   1 # Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
   2 # Contributor: Tom Gundersen <teg@jklm.no>
   3 # Contributor: Thomas Baechler <thomas@archlinux.org>
   4
   5 pkgname=libfprint
   6 pkgver=1.94.5
   7 pkgrel=1
   8 pkgdesc="Library for fingerprint readers"
   9 url="https://fprint.freedesktop.org/"
  10 arch=(x86_64)
  11 license=(LGPL)
  12 depends=(libgusb pixman nss systemd libgudev)
  13 makedepends=(git meson gtk-doc gobject-introspection)
  14 checkdepends=(cairo)
  15 provides=(libfprint-2.so)
  16 groups=(fprint)
  17 options=(debug)
  18 _commit=86961a9429d589c387da37351fd6b4ff3caf67ea  # tags/v1.94.5^0
  19 source=("git+https://gitlab.freedesktop.org/libfprint/libfprint.git#commit=$_commit")
  20 sha256sums=('SKIP')
  21
  22 pkgver() {
  23   cd $pkgname
  24   git describe --tags | sed 's/^v//;s/^V_//;s/_/./g;s/[^-]*-g/r&/;s/-/+/g'
  25 }
  26
  27 prepare() {
  28   cd $pkgname
  29 }
  30
  31 build() {
  32   arch-meson $pkgname build
  33   meson compile -C build
  34 }
  35
  36 check() {
  37   meson test -C build --print-errorlogs
  38 }
  39
  40 package() {
  41   meson install -C build --destdir "$pkgdir"
  42 }
  43
  44 # vim:set sw=2 sts=-1 et: