libgnomekbd/repos/extra-x86_64/PKGBUILD

   1 # Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
   2 # Contributor: Jan de Groot <jgc@archlinux.org>
   3
   4 pkgname=libgnomekbd
   5 pkgver=3.28.1
   6 pkgrel=1
   7 epoch=1
   8 pkgdesc="Keyboard management library"
   9 url="https://gitlab.gnome.org/GNOME/libgnomekbd"
  10 arch=(x86_64)
  11 license=(LGPL)
  12 depends=(libxklavier gtk3 dconf)
  13 makedepends=(gobject-introspection git meson)
  14 provides=(libgnomekbd{,ui}.so)
  15 options=(debug)
  16 _commit=1ca55e9f3644eb20ccee1042a7fa4158465f4aef  # tags/3.28.1^0
  17 source=("git+https://gitlab.gnome.org/GNOME/libgnomekbd.git#commit=$_commit"
  18         meson.diff)
  19 sha256sums=('SKIP'
  20             'd41afc90476de55e1281172b538aa764a4697ff487d11660a7b02503c0630430')
  21
  22 pkgver() {
  23   cd $pkgname
  24   git describe --tags | sed 's/[^-]*-g/r&/;s/-/+/g'
  25 }
  26
  27 prepare() {
  28   cd $pkgname
  29
  30   # Fixes for meson build
  31   git apply -3 ../meson.diff
  32 }
  33
  34 build() {
  35   arch-meson $pkgname build
  36   meson compile -C build
  37 }
  38
  39 check() {
  40   meson test -C build --print-errorlogs
  41 }
  42
  43 package() {
  44   meson install -C build --destdir "$pkgdir"
  45 }
  46
  47 # vim:set sw=2 sts=-1 et: