libgsf/trunk/PKGBUILD

   1 # Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
   2 # Contributor: Jan de Groot <jgc@archlinux.org>
   3 # Contributor: Sarah Hay <sarahhay@mb.sympatico.ca>
   4
   5 pkgname=libgsf
   6 pkgver=1.14.50
   7 pkgrel=1
   8 arch=(x86_64)
   9 pkgdesc="An extensible I/O abstraction library for dealing with structured file formats"
  10 url="https://gitlab.gnome.org/GNOME/libgsf"
  11 license=(GPL LGPL)
  12 depends=(libxml2 gdk-pixbuf2 bzip2)
  13 makedepends=(gobject-introspection git gtk-doc autoconf-archive)
  14 checkdepends=(perl-xml-parser unzip valgrind)
  15 provides=(libgsf-1.so)
  16 _commit=3f6b8dc6f2ba395eeb0dc3c2ebc60c14105be3e1  # tags/LIBGSF_1_14_50^0
  17 source=("git+https://gitlab.gnome.org/GNOME/libgsf.git#commit=$_commit")
  18 sha256sums=('SKIP')
  19
  20 pkgver() {
  21   cd libgsf
  22   git describe --tags | sed 's/^LIBGSF_//;s/_/./g;s/[^-]*-g/r&/;s/-/+/g'
  23 }
  24
  25 prepare() {
  26   cd libgsf
  27   NOCONFIGURE=1 ./autogen.sh
  28 }
  29
  30 build() {
  31   local configure_options=(
  32     --prefix=/usr
  33     --sysconfdir=/etc
  34     --localstatedir=/var
  35     --disable-static
  36     --enable-introspection
  37     --enable-gtk-doc
  38   )
  39
  40   cd libgsf
  41   ./configure "${configure_options[@]}"
  42   sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
  43   make
  44 }
  45
  46 check() {
  47   cd libgsf
  48   make check
  49 }
  50
  51 package_libgsf() {
  52   cd libgsf
  53   make DESTDIR="$pkgdir" install
  54 }
  55
  56 # vim:set sw=2 sts=-1 et: