libmspack/trunk/PKGBUILD

   1 # Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
   2 # Contributor: AndyRTR <andyrtr@archlinux.org>
   3
   4 pkgname=libmspack
   5 _tag='9d29d849d0b272eaf66c1e4811f573492fea035f' # rev-parse tags/v0.11alpha
   6 epoch=1
   7 pkgver=0.11alpha
   8 pkgrel=1
   9 pkgdesc='A library for Microsoft compression formats'
  10 url='https://www.cabextract.org.uk/libmspack/'
  11 arch=('x86_64')
  12 license=('GPL')
  13 depends=('glibc')
  14 makedepends=('git')
  15 provides=('libmspack.so')
  16 source=("git+https://github.com/kyz/libmspack#tag=$_tag")
  17 sha256sums=('SKIP')
  18
  19 pkgver() {
  20   cd $pkgname
  21   git describe --tags | sed 's/^v//;s/[^-]*-g/r&/;s/-/+/g'
  22 }
  23
  24 prepare() {
  25   cd $pkgname/$pkgname
  26   autoreconf -vfi
  27 }
  28
  29 build() {
  30   cd $pkgname/$pkgname
  31   ./configure \
  32     --prefix=/usr \
  33     --sysconfdir=/etc \
  34     --localstatedir=/var \
  35     --disable-static
  36   sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
  37   make
  38 }
  39
  40 check() {
  41   cd $pkgname/$pkgname
  42   make check
  43 }
  44
  45 package() {
  46   cd $pkgname/$pkgname
  47   make DESTDIR="$pkgdir" install
  48 }
  49
  50 # vim:set sw=2 sts=-1 et: