libmwaw/repos/extra-x86_64/PKGBUILD

   1 # Maintainer: AndyRTR <andyrtr@archlinux.org>
   2 # Contributor: Thomas Arnhold <thomas at arnhold dot org>
   3
   4 pkgbase=libmwaw
   5 pkgname=('libmwaw' 'libmwaw-docs')
   6 pkgver=0.3.22
   7 pkgrel=1
   8 pkgdesc="Import library for some old mac text documents."
   9 arch=('x86_64')
  10 url="https://sourceforge.net/projects/libmwaw/"
  11 license=('LGPL2.1' 'MPL')
  12 makedepends=('librevenge' 'doxygen')
  13 source=(https://sourceforge.net/projects/${pkgname}/files/${pkgname}/${pkgname}-${pkgver}/${pkgname}-${pkgver}.tar.xz)
  14 sha1sums=('86bc49bfc8766cdcb079d46ca9c874e0d4c1f9d4')
  15 sha256sums=('a1a39ffcea3ff2a7a7aae0c23877ddf4918b554bf82b0de5d7ce8e7f61ea8e32')
  16
  17 build() {
  18   cd "${pkgname}"-${pkgver}
  19   ./configure --prefix=/usr
  20   make
  21 }
  22
  23 check() {
  24   cd "${pkgname}"-${pkgver}
  25   make check
  26 }
  27
  28 package_libmwaw() {
  29
  30   depends=('librevenge')
  31
  32   cd "${pkgname}"-${pkgver}
  33   make DESTDIR="$pkgdir" install
  34
  35   # Split -docs
  36   mkdir -p ../docs/usr/share
  37   mv -t ../docs/usr/share "$pkgdir"/usr/share/doc
  38   rmdir "$pkgdir"/usr/share
  39 }
  40
  41 package_libmwaw-docs() {
  42
  43   pkgdesc+=" (documentation)"
  44
  45   mv -t "$pkgdir" docs/*
  46 }