libnice/trunk/PKGBUILD

   1 # Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
   2 # Contributor: Ionut Biru <ibiru@archlinux.org>
   3 # Contributor: William Díaz <wdiaz@archlinux.us>
   4
   5 pkgname=libnice
   6 pkgver=0.1.21
   7 pkgrel=2
   8 pkgdesc="An implementation of the IETF's draft ICE (for p2p UDP data streams)"
   9 url="https://nice.freedesktop.org"
  10 arch=(x86_64)
  11 license=(LGPL)
  12 depends=(
  13   glib2
  14   gnutls
  15   gupnp-igd
  16 )
  17 makedepends=(
  18   git
  19   gobject-introspection
  20   graphviz
  21   gstreamer
  22   gtk-doc
  23   meson
  24 )
  25 optdepends=('gstreamer: "nice" GStreamer plugin')
  26 provides=(libnice.so)
  27 _commit=3d9cae16a5094aadb1651572644cb5786a8b4e2d  # tags/0.1.21^0
  28 source=("git+https://gitlab.freedesktop.org/libnice/libnice.git#commit=$_commit")
  29 b2sums=('SKIP')
  30
  31 pkgver() {
  32   cd libnice
  33   git describe --tags | sed 's/[^-]*-g/r&/;s/-/+/g'
  34 }
  35
  36 prepare() {
  37   cd libnice
  38
  39   # GUPnP-IGD 1.6
  40   sed -i 's/gupnp-igd-1\.0/gupnp-igd-1.6/' meson.build
  41 }
  42
  43 build() {
  44   arch-meson libnice build -D gtk_doc=enabled
  45   meson compile -C build
  46 }
  47
  48 check() {
  49   meson test -C build --print-errorlogs
  50 }
  51
  52 package() {
  53   meson install -C build --destdir "$pkgdir"
  54 }
  55
  56 # vim:set sw=2 sts=-1 et: