libshumate/trunk/PKGBUILD

   1 # Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
   2
   3 pkgbase=libshumate
   4 pkgname=(libshumate libshumate-docs)
   5 pkgver=1.0.3
   6 pkgrel=1
   7 pkgdesc="Map widget for GTK 4"
   8 url="https://wiki.gnome.org/Projects/libshumate"
   9 license=(LGPL)
  10 arch=(x86_64)
  11 depends=(glib2 cairo sqlite gtk4 libsoup3)
  12 makedepends=(gobject-introspection gi-docgen vala meson git)
  13 checkdepends=(xorg-server-xvfb)
  14 _commit=55d89e24de5086404b996a73e94cd56ee2e9541a  # tags/1.0.3^0
  15 source=("git+https://gitlab.gnome.org/GNOME/libshumate.git#commit=$_commit")
  16 sha256sums=('SKIP')
  17
  18 pkgver() {
  19   cd $pkgname
  20   git describe --tags | sed 's/[^-]*-g/r&/;s/-/+/g'
  21 }
  22
  23 prepare() {
  24   cd $pkgname
  25 }
  26
  27 build() {
  28   local meson_options=(
  29     -D demos=true
  30   )
  31
  32   arch-meson $pkgname build "${meson_options[@]}"
  33   meson compile -C build
  34 }
  35
  36 check() {
  37   xvfb-run -s '-nolisten local' \
  38     meson test -C build --print-errorlogs
  39 }
  40
  41 package_libshumate() {
  42   provides=(libshumate-1.0.so)
  43
  44   meson install -C build --destdir "$pkgdir"
  45
  46   mkdir -p doc/usr/share
  47   mv {"$pkgdir",doc}/usr/share/doc
  48 }
  49
  50 package_libshumate-docs() {
  51   pkgdesc+=" (documentation)"
  52   depends=()
  53
  54   mv doc/* "$pkgdir"
  55 }
  56
  57 # vim:set sw=2 sts=-1 et: