libsigc++/trunk/PKGBUILD

   1 # Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
   2 # Contributor: Jan de Groot <jgc@archlinux.org>
   3 # Contributor: Tom Newsom <Jeepster@gmx.co.uk>
   4
   5 pkgbase=libsigc++
   6 pkgname=(libsigc++ libsigc++-docs)
   7 pkgver=2.12.0
   8 pkgrel=1
   9 pkgdesc="Callback Framework for C++"
  10 url="https://libsigcplusplus.github.io/libsigcplusplus/"
  11 arch=(x86_64)
  12 license=(LGPL)
  13 depends=(gcc-libs)
  14 makedepends=(git meson mm-common)
  15 options=(!emptydirs)
  16 _commit=9ae288305b16e4aee2d2ea1fcfb5968c924fa219  # tags/2.12.0^0
  17 source=("git+https://github.com/libsigcplusplus/libsigcplusplus#commit=$_commit")
  18 sha256sums=('SKIP')
  19
  20 pkgver() {
  21   cd libsigcplusplus
  22   git describe --tags | sed 's/-/+/g'
  23 }
  24
  25 prepare() {
  26   cd libsigcplusplus
  27 }
  28
  29 build() {
  30   arch-meson libsigcplusplus build -D maintainer-mode=true
  31   meson compile -C build
  32 }
  33
  34 check() {
  35   meson test -C build --print-errorlogs
  36 }
  37
  38 # Do not remove the space before the () or commitpkg will
  39 # accidentally to run this function on the system (!!!)
  40 package_libsigc++ () {
  41   provides=("libsigc++2.0=$pkgver" libsigc-2.0.so)
  42   conflicts=(libsigc++2.0)
  43   replaces=(libsigc++2.0)
  44
  45   meson install -C build --destdir "$pkgdir"
  46
  47   # Split -docs
  48   mkdir -p docs/usr/share
  49   mv -t docs/usr/share "$pkgdir"/usr/share/{devhelp,doc}
  50 }
  51
  52 package_libsigc++-docs() {
  53   pkgdesc+=" (documentation)"
  54   depends=()
  55   provides=("libsigc++2.0-docs=$pkgver")
  56   conflicts=(libsigc++2.0-docs)
  57   replaces=(libsigc++2.0-docs)
  58   options=(!strip)
  59
  60   mv -t "$pkgdir" docs/*
  61 }