libsoup/repos/extra-x86_64/PKGBUILD

   1 # Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
   2 # Contributor: Jan de Groot <jgc@archlinux.org>
   3
   4 pkgbase=libsoup
   5 pkgname=(libsoup libsoup-docs)
   6 pkgver=2.74.3
   7 pkgrel=1
   8 pkgdesc="HTTP client/server library for GNOME"
   9 url="https://wiki.gnome.org/Projects/libsoup"
  10 arch=(x86_64)
  11 license=(LGPL)
  12 depends=(
  13   brotli
  14   glib-networking
  15   glib2
  16   krb5
  17   libpsl
  18   libsysprof-capture
  19   libxml2
  20   sqlite
  21 )
  22 makedepends=(
  23   git
  24   gobject-introspection
  25   gtk-doc
  26   meson
  27   samba
  28   vala
  29 )
  30 checkdepends=(
  31   apache
  32   php-apache
  33 )
  34 options=(debug)
  35 _commit=4a6b9178ded85e269872ffedfb2b18f2754a75d9  # tags/2.74.3^0
  36 source=("git+https://gitlab.gnome.org/GNOME/libsoup.git#commit=$_commit"
  37         disable-flaky-test.diff)
  38 b2sums=('SKIP'
  39         '4d71171b26ed107884a22696f9df1609c45c377e27baaaeb4ec5d890f9fbd62f09607ba3da0acdb42b4f86b9e828014471e6731437ec80de3b6ad98d7f0a2f60')
  40
  41 pkgver() {
  42   cd libsoup
  43   git describe --tags | sed 's/[^-]*-g/r&/;s/-/+/g'
  44 }
  45
  46 prepare() {
  47   cd libsoup
  48
  49   # https://gitlab.gnome.org/GNOME/libsoup/-/issues/120
  50   git apply -3 ../disable-flaky-test.diff
  51 }
  52
  53 build() {
  54   local meson_options=(
  55     -D gtk_doc=true
  56   )
  57   arch-meson libsoup build "${meson_options[@]}"
  58   meson compile -C build
  59 }
  60
  61 check() {
  62   meson test -C build --print-errorlogs
  63 }
  64
  65 package_libsoup() {
  66   depends+=(
  67     libbrotlidec.so
  68     libgssapi_krb5.so
  69     libg{lib,object,io}-2.0.so
  70     libpsl.so
  71   )
  72   optdepends=('samba: Windows Domain SSO')
  73   provides+=(libsoup{,-gnome}-2.4.so)
  74
  75   meson install -C build --destdir "$pkgdir"
  76
  77   mkdir -p doc/usr/share
  78   mv {"$pkgdir",doc}/usr/share/gtk-doc
  79 }
  80
  81 package_libsoup-docs() {
  82   pkgdesc+=" (documentation)"
  83   depends=()
  84
  85   mv doc/* "$pkgdir"
  86 }
  87
  88 # vim:set sw=2 sts=-1 et: