libxcrypt/repos/core-x86_64/PKGBUILD

   1 # Maintainer: Christian Hesse <mail@eworm.de>
   2
   3 pkgbase=libxcrypt
   4 pkgname=(libxcrypt libxcrypt-compat)
   5 pkgver=4.4.33
   6 pkgrel=1
   7 pkgdesc='Modern library for one-way hashing of passwords'
   8 arch=('x86_64')
   9 url='https://github.com/besser82/libxcrypt/'
  10 license=('GPL')
  11 depends=('glibc')
  12 provides=('libcrypt.so')
  13 options=('debug')
  14 install=libxcrypt.install
  15 validpgpkeys=('678CE3FEE430311596DB8C16F52E98007594C21D') # Björn 'besser82' Esser
  16 source=("${url}/releases/download/v${pkgver}/${pkgbase}-${pkgver}.tar.xz"{,.asc})
  17 sha256sums=('e87acf9c652c573a4713d5582159f98f305d56ed5f754ce64f57d4194d6b3a6f'
  18             'SKIP')
  19
  20 build() {
  21   mkdir build-libxcrypt build-libxcrypt-compat
  22
  23   cd "${srcdir}/build-libxcrypt/"
  24   "${srcdir}/${pkgbase}-${pkgver}"/configure \
  25     --prefix=/usr \
  26     --disable-static \
  27     --enable-hashes=strong,glibc \
  28     --enable-obsolete-api=no \
  29     --disable-failure-tokens
  30   make
  31
  32   cd "${srcdir}/build-libxcrypt-compat/"
  33   "${srcdir}/${pkgbase}-${pkgver}"/configure \
  34     --prefix=/usr \
  35     --disable-static \
  36     --enable-hashes=strong,glibc \
  37     --enable-obsolete-api=glibc \
  38     --disable-failure-tokens
  39   make
  40 }
  41
  42 check() {
  43   cd build-libxcrypt/
  44
  45   make check
  46 }
  47
  48 package_libxcrypt() {
  49   cd build-libxcrypt/
  50
  51   make DESTDIR="${pkgdir}" install
  52 }
  53
  54 package_libxcrypt-compat() {
  55   pkgdesc='Modern library for one-way hashing of passwords - legacy API functions'
  56   depends=('libxcrypt')
  57
  58   cd build-libxcrypt-compat/
  59
  60   make DESTDIR="${pkgdir}" install
  61
  62   rm -rf "${pkgdir}"/usr/{include,lib/{lib*.so,pkgconfig},share}
  63 }