libxklavier/repos/extra-x86_64/PKGBUILD

   1 # Maintainer: Jan de Groot <jgc@archlinux.org>
   2 # Contributor: Arjan Timmerman <arjan@archlinux.org>
   3
   4 pkgname=libxklavier
   5 pkgver=5.4
   6 pkgrel=4
   7 pkgdesc="High-level API for X Keyboard Extension"
   8 arch=(x86_64)
   9 license=('LGPL')
  10 depends=('glib2' 'libxkbfile' 'libxml2' 'xkeyboard-config' 'libxi' 'iso-codes')
  11 makedepends=('gobject-introspection' 'intltool' 'gtk-doc' 'libxfixes' git)
  12 options=('!emptydirs')
  13 url="https://www.freedesktop.org/wiki/Software/LibXklavier/"
  14 _commit=396955bd2ba2db34a42b3807b03155fcc11dfe50  # tags/libxklavier-5.4^0
  15 source=("git+https://anongit.freedesktop.org/git/libxklavier#commit=$_commit")
  16 sha256sums=('SKIP')
  17
  18 pkgver() {
  19   cd $pkgname
  20   git describe --tags | sed 's/^libxklavier-//;s/-/+/g'
  21 }
  22
  23 build() {
  24   cd "$pkgname"
  25   ./autogen.sh --prefix=/usr --with-xkb-bin-base=/usr/bin \
  26       --with-xkb-base=/usr/share/X11/xkb --disable-static --enable-gtk-doc
  27   make
  28 }
  29
  30 package() {
  31   cd "$pkgname"
  32   make DESTDIR="$pkgdir" install
  33 }