libxp/trunk/PKGBUILD

   1 # Maintainer: AndyRTR <andyrtr@archlinux.org>
   2 # Contributor: Jan de Groot <jgc@archlinux.org>
   3
   4 pkgname=libxp
   5 pkgver=1.0.4
   6 pkgrel=2
   7 pkgdesc="X11 X Print Library"
   8 arch=('x86_64')
   9 license=('custom')
  10 url="https://xorg.freedesktop.org/"
  11 depends=('libxext')
  12 makedepends=('xorg-util-macros' 'xorgproto')
  13 provides=('libXp.so')
  14 source=(${url}/releases/individual/lib/libXp-${pkgver}.tar.xz{,.sig}
  15         add-proto-files.patch)
  16 sha512sums=('50e82e7ee7222db13a04f6223ae8653eb783593c3b28825d7fc233af188960bec53d2b11ced281e01140d283d840d0e3822d71f95f5045d594fb704485fd0f89'
  17             'SKIP'
  18             '4347b6928d9cffa610e8dec7524d3897d2bbcdb6ee24a1e801bb28a5c5dc0a7a692cb1d0d5dddca2cbf6484c3604bbb3b3b4b62cd566d807167c3636b2247004')
  19 #validpgpkeys=('3BB639E56F861FA2E86505690FDD682D974CA72A') #  "Matt Turner <mattst88@gmail.com>"
  20 validpgpkeys=('4A193C06D35E7C670FA4EF0BA2FB9E081F2D130E') # Alan Coopersmith <alan.coopersmith@oracle.com>
  21
  22 prepare() {
  23   cd libXp-${pkgver}
  24   patch -Np1 -i ../add-proto-files.patch
  25   autoreconf -vfi
  26 }
  27
  28 build() {
  29   cd libXp-${pkgver}
  30   ./configure --prefix=/usr
  31   make
  32 }
  33
  34 package() {
  35   cd libXp-${pkgver}
  36   make DESTDIR="${pkgdir}" install
  37   install -m755 -d "${pkgdir}/usr/share/licenses/${pkgname}"
  38   install -m644 COPYING "${pkgdir}/usr/share/licenses/${pkgname}/"
  39 }