libxslt/repos/extra-x86_64/PKGBUILD

   1 # Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
   2 # Contributor: Eric Belanger <eric@archlinux.org>
   3 # Contributor: John Proctor <jproctor@prium.net>
   4
   5 pkgbase=libxslt
   6 pkgname=(libxslt libxslt-docs)
   7 pkgver=1.1.37
   8 pkgrel=3
   9 pkgdesc="XML stylesheet transformation library"
  10 url="https://gitlab.gnome.org/GNOME/libxslt/-/wikis/home"
  11 arch=(x86_64)
  12 license=(custom:MIT)
  13 depends=(
  14   libgcrypt
  15   libxml2
  16   xz
  17 )
  18 makedepends=(
  19   git
  20   python
  21 )
  22 checkdepends=(
  23   docbook-xml
  24 )
  25 _commit=5eca7fb65b7337409a02f9f94fde608edf7d1b0a  # tags/v1.1.37^0
  26 source=("git+https://gitlab.gnome.org/GNOME/libxslt.git#commit=$_commit"
  27         0001-Make-generate-id-deterministic.patch)
  28 sha256sums=('SKIP'
  29             '605e0a0b2ca385a90226bc5b141d3f6bfeade13e43ab39f8dea863505d7cbf18')
  30
  31 pkgver() {
  32   cd libxslt
  33   git describe --tags | sed 's/-rc/rc/;s/^v//;s/[^-]*-g/r&/;s/-/+/g'
  34 }
  35
  36 prepare() {
  37   cd libxslt
  38
  39   # Make xsltproc output reproducible for packages which use it to generate documentation
  40   git apply -3 ../0001-Make-generate-id-deterministic.patch
  41
  42   NOCONFIGURE=1 ./autogen.sh
  43 }
  44
  45 build() {
  46   cd libxslt
  47
  48   ./configure \
  49     --prefix=/usr \
  50     --sysconfdir=/etc \
  51     --localstatedir=/var \
  52     --with-python=/usr/bin/python \
  53     --disable-static
  54   sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
  55   make
  56 }
  57
  58 check() {
  59   cd libxslt
  60   make check
  61 }
  62
  63 package_libxslt() {
  64   optdepends=('python: Python bindings')
  65   provides=(lib{,e}xslt.so)
  66
  67   cd libxslt
  68
  69   make DESTDIR="$pkgdir" install
  70
  71   mkdir -p ../doc/usr/share
  72   mv "$pkgdir"/usr/share/{doc,gtk-doc} -t ../doc/usr/share
  73
  74   install -Dm644 Copyright -t "$pkgdir/usr/share/licenses/$pkgname"
  75 }
  76
  77 package_libxslt-docs() {
  78   pkgdesc+=" (documentation)"
  79   depends=()
  80
  81   mv doc/* "$pkgdir"
  82
  83   install -Dm644 libxslt/Copyright -t "$pkgdir/usr/share/licenses/$pkgname"
  84 }
  85
  86 # vim:set sw=2 sts=-1 et: