liferea/trunk/PKGBUILD

   1 # Maintainer: Eric Bélanger <eric@archlinux.org>
   2
   3 pkgname=liferea
   4 pkgver=1.14.5
   5 pkgrel=1
   6 pkgdesc="A desktop news aggregator for online news feeds and weblogs"
   7 arch=('x86_64')
   8 url="https://lzone.de/liferea"
   9 license=('GPL')
  10 depends=('webkit2gtk' 'libpeas' 'python-gobject')
  11 makedepends=('intltool' 'gobject-introspection')
  12 optdepends=('libsecret: for keyring plugin support'
  13             'python-cairo: for the tray icon plugin'
  14             'gst-plugins-base: for media player plugin support'
  15             'gst-plugins-good: for media player plugin support'
  16             'gst-plugins-bad: for media player plugin support')
  17 options=('!emptydirs')
  18 source=(https://github.com/lwindolf/liferea/releases/download/v$pkgver/$pkgname-${pkgver}.tar.bz2)
  19 sha256sums=('2244e78d8f6b6e28f411a3554d61496a012d5fe1392fe1b475978ecfd8c61177')
  20
  21 build() {
  22   cd $pkgname-${pkgver}
  23
  24   ./configure --prefix=/usr \
  25     --sysconfdir=/etc \
  26     --localstatedir=/var \
  27     --disable-schemas-compile
  28   make
  29 }
  30
  31 package() {
  32   cd $pkgname-${pkgver}
  33   make DESTDIR="${pkgdir}" install
  34 }