nautilus-sendto/repos/extra-x86_64/PKGBUILD

   1 # Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
   2 # Contributor: Jan de Groot <jgc@archlinux.org>
   3 # Contributor: Eduardo Romero <eduardo@archlinux.org>
   4 # Contributor: Tor Krill <tor@krill.nu>
   5
   6 pkgname=nautilus-sendto
   7 pkgver=3.8.6+28+gc87aac4
   8 pkgrel=1
   9 pkgdesc="Easily send files via mail"
  10 url="https://gitlab.gnome.org/Archive/nautilus-sendto"
  11 arch=(x86_64)
  12 license=(GPL)
  13 depends=(glib2)
  14 makedepends=(gobject-introspection git meson appstream-glib)
  15 _commit=c87aac46c4893e09b1ced1cca8bb86b0a6823124  # master
  16 source=("git+https://gitlab.gnome.org/Archive/nautilus-sendto.git#commit=$_commit")
  17 sha256sums=('SKIP')
  18
  19 pkgver() {
  20   cd $pkgname
  21   git describe --tags | sed 's/^NAUTILUS_SENDTO_//;s/_/./g;s/-/+/g'
  22 }
  23
  24 prepare() {
  25   cd $pkgname
  26 }
  27
  28 build() {
  29   arch-meson $pkgname build
  30   meson compile -C build
  31 }
  32
  33 check() {
  34   meson test -C build
  35 }
  36
  37 package() {
  38   DESTDIR="$pkgdir" meson install -C build
  39 }
  40
  41 # vim:set sw=2 et: