ncftp/trunk/PKGBUILD

   1 # Maintainer: Lukas Fleischer <lfleischer@archlinux.org>
   2 # Contributor: Andrea Scarpino <andrea@archlinux.org>
   3 # Contributor: Paul Mattal <paul@archlinux.org>
   4 # Contributor: Tom Newsom <Jeepster@gmx.co.uk>
   5
   6 pkgname=ncftp
   7 pkgver=3.2.6
   8 pkgrel=5
   9 pkgdesc="A set of free application programs implementing FTP"
  10 url="https://www.ncftp.com/"
  11 arch=('x86_64')
  12 license=('custom')
  13 depends=('ncurses')
  14 source=("ftp://ftp.ncftp.com/ncftp/$pkgname-$pkgver-src.tar.xz"
  15         ncftp-reproducible.patch)
  16 sha256sums=('5f200687c05d0807690d9fb770327b226f02dd86155b49e750853fce4e31098d'
  17             'd5df31ab43f1573a86a842fdc69d7ae84f20afd22c74336264cc4e1e39e2f44d')
  18
  19 prepare() {
  20   cd "${pkgname}-${pkgver}"
  21   # Make ncftp reproducible by not compiling in the kernel version
  22   patch -Np1 -i "${srcdir}/ncftp-reproducible.patch"
  23 }
  24
  25 build() {
  26   cd "${pkgname}-${pkgver}"
  27
  28   CFLAGS+=' -fcommon' # https://wiki.gentoo.org/wiki/Gcc_10_porting_notes/fno_common
  29
  30   # FS#39211
  31   unset CPPFLAGS
  32
  33   CPP=/usr/bin/cpp ./configure --prefix=/usr --sysconfdir=/etc
  34   make
  35 }
  36
  37 package() {
  38   cd "${pkgname}-${pkgver}"
  39
  40   install -d "${pkgdir}/usr/share"
  41   make prefix="${pkgdir}/usr" mandir="${pkgdir}/usr/share/man" install
  42   install -Dm644 doc/LICENSE.txt "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
  43 }